Question

我正在寻找一种方法，以将IRAM的优先级赋予特定的源文件，并在默认情况下让其他源文件使用。

在Keil uVision中，我可以通过进入文件选项来实现它：

我将项目迁移到了Atollic TrueSTUDIO（由CubeMx生成），没有类似的选择。我在链接描述文件STM32F765NG_FLASH.id中找到了有关如何设置RAM起始位置及其大小的信息。

/* Specify the memory areas */
MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 512K
FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 1024K
}

我想也许有一种方法可以修改此文件，以指定哪个.c文件需要IRAM上的优先级，但是我不知道在哪里以及如何做。

我还发现了可以在变量声明中使用的__ attribute__。当我使用它时，它可以编译，但是破坏了代码的某些功能（它可能会覆盖其他数据）。

uint8_t __attribute__((section(".ARM.__at_0x20000000"))) RxSerialDMABuffer[RX_DMA_BUFFER_SIZE] = {0};
uint8_t __attribute__((section(".ARM.__at_0x20001000"))) TxDMABuffer[TX_DMA_BUFFER_SIZE] = {0};

所以我的问题是，如何在没有Keil uVision选项的情况下，如何将特定的源文件设置为优先使用IRAM，而不要使用其他所有文件？

编辑：这是完整的链接程序脚本

/*
*****************************************************************************
**

**  File        : stm32_flash.ld
**
**  Abstract    : Linker script for STM32F765NG Device with
**                1024KByte FLASH, 512KByte RAM
**
**                Set heap size, stack size and stack location according
**                to application requirements.
**
**                Set memory bank area and size if external memory is used.
**
**  Target      : STMicroelectronics STM32
**
**  Environment : Atollic TrueSTUDIO(R)
**
**  Distribution: The file is distributed as is, without any warranty
**                of any kind.
**
**  (c)Copyright Atollic AB.
**  You may use this file as-is or modify it according to the needs of your
**  project. This file may only be built (assembled or compiled and linked)
**  using the Atollic TrueSTUDIO(R) product. The use of this file together
**  with other tools than Atollic TrueSTUDIO(R) is not permitted.
**
*****************************************************************************
*/

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x20080000;    /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0x00002200;      /* required amount of heap  */
_Min_Stack_Size = 0x00001200; /* required amount of stack */

/* Specify the memory areas */
MEMORY
{
RAM (xrw)      : ORIGIN = 0x20000000, LENGTH = 512K
FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 1024K
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.glue_7)         /* glue arm to thumb code */
    *(.glue_7t)        /* glue thumb to arm code */
    *(.eh_frame)

    KEEP (*(.init))
    KEEP (*(.fini))

    . = ALIGN(4);
    _etext = .;        /* define a global symbols at end of code */
  } >FLASH

  /* Constant data goes into FLASH */
  .rodata :
  {
    . = ALIGN(4);
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    . = ALIGN(4);
  } >FLASH

  .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  .ARM : {
    __exidx_start = .;
    *(.ARM.exidx*)
    __exidx_end = .;
  } >FLASH

  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH

  /* used by the startup to initialize data */
  _sidata = LOADADDR(.data);

  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data : 
  {
    . = ALIGN(4);
    _sdata = .;        /* create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */

    . = ALIGN(4);
    _edata = .;        /* define a global symbol at data end */
  } >RAM AT> FLASH


  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(4);
    PROVIDE ( end = . );
    PROVIDE ( _end = . );
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(4);
  } >RAM



  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }

  .ARM.attributes 0 : { *(.ARM.attributes) }
}

Answer 1

TrueSTUDIO使用GNU工具链，因此GNU linker documentation适用。特别是在处理section placement的部分。

类似的东西（请注意，下面是一个片段；您的实际链接描述文件将包含更多内容或组织方式不同）：

MEMORY
{
    ...

    IRAM1 (xrw)       : ORIGIN = 0x20020000, LENGTH = 384K
    IRAM2 (xrw)       : ORIGIN = 0x20000000, LENGTH = 128K
}

SECTIONS
{
   DATA_IRAM1 :
   {
      * (.data)

   } > IRAM1 AT > FLASH

   BSS_IRAM1 :
   {
      * (.bss)

   } > IRAM1

   DATA_IRAM2 :
   {
      Buffers.o (.data) /* locate Buffers initialised data here */ 
      * (.data)

   } > IRAM2 AT > FLASH

   BSS_IRAM2 :
   {
      Buffers.o (.bss) /* locate Buffers zero-int data here */ 
      * (.bss)  

   } > IRAM2
}

通配符* (.bss)允许任何对象模块的BSS位于指定的部分，而Buffers.o (.bss)使Buffers.o BSS的位置明确。对于.data同样。

如果您查看由Keil生成的链接描述文件，您会发现它直接受到GUI对话框中设置的影响，并且会看到类似的指令-但是ARM链接器使用的语法与我认为的GNU略有不同，但是查看它如何组织您特定部分的内存和位置可能会有所帮助-您发布的片段似乎有些通用，并且不会将IRAM分成例如其专业部分（例如TCM）。

Answer 2

要将RAM的优先级分配给我的缓冲区，我先将它们加载到RAM中。

通过使用文件名，链接器报告了多个定义的错误。因此，像在问题中一样，我向缓冲区中添加了一个section属性，但使用了节名称而不是地址。

uint8_t RxSerialDMABuffer[RX_DMA_BUFFER_SIZE] __attribute__ ((section ("BUFFERS"))) = {0};
uint8_t TxDMABuffer[TX_DMA_BUFFER_SIZE] __attribute__ ((section ("BUFFERS"))) = {0};

此后，我在RAM中的其他未初始化数据之前添加了新节。

  /* Uninitialized buffers section */
  .BUFFERS :
  {
    * (.BUFFERS)
  } >RAM

  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM

然后我进入了链接器地址映射文件，我看到了所有缓冲区的地址与我的IRAM2地址范围相对应，所有其他未初始化的数据都具有IRAM2中的下一个地址，然后是IRAM1。

将IRAM的优先级赋予C中的特定源文件

2 个答案: