Question

当名称很少时，在Stata中循环很容易。

此外，如果有关于名称更改（例如递增）的规则，我可以执行以下操作：

forval i = 1/5 {
    ...
}

但是，在某些情况下，我需要遍历数百个名称，而没有递增规则。

例如：

48700 48900 48999 49020 49180 49340 ...

是否有一些简便的编写循环的方式？还是我只需要刻苦列出所有这些人？

Answer 1

答案是这取决于。

如果这些是变量名的一部分，则可以执行以下操作：

clear
set obs 5

foreach var in 48700 48900 48999 49020 49180 49340 {
    generate var`var' = runiform()
}

ds
var48700  var48900  var48999  var49020  var49180  var49340

ds var48*
var48700  var48900  var48999

local names `r(varlist)'

foreach var of local names {
    display `var'
}

.41988069
.06420179
.36276805

如果这些是文件名，则可以使用宏扩展功能：

dir, w

48700.rtf       48999.rtf       49180.rtf
48900.rtf       49020.rtf       49340.rtf

local list : dir . files "*"
display `list'
48700.rtf48900.rtf48999.rtf49020.rtf49180.rtf49340.rtf

local list : dir . files "48*"
display `list'
48700.rtf48900.rtf48999.rtf

foreach fil of local list {
    display "`fil'"
}
48700.rtf
48900.rtf
48999.rtf

编辑：

上述方法涉及如何有效地获取本地宏中的所有相关名称。

如果您已经知道名称，并且只想以更简洁的方式编写循环（或想在多个循环中重复使用名称），则可以自己在本地宏中分配这些名称：

local names var48700 var48900 var48999 var49020 var49180 var49340

foreach var of local names {
    display `var'
}

.41988069
.06420179
.36276805
.52763051
.16493952
.66403782

本地宏names将在运行时自动扩展以包括所有指定的项目。

遍历许多没有规则的名称

1 个答案: