Question

我对Weblogic12有很大的问题。我试图运行Admin Server，命令行消失了，没有任何信息。所以我在对其进行了更深入的调试，在shortPaths.cmd文件中出现了一个问题，如下所示：

@rem **************************************************************************
@rem This script is used to shorten CLASSPATH and PATH environmental variables.
@rem 
@rem Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved. 
@rem **************************************************************************
if NOT "%CLASSPATH%"=="" (
  call :handle_classpath
)

if NOT "%PATH%"=="" (
  call :handle_path
)
goto :EOF

:handle_classpath
pause
  set __SHORT_CLASSPATH__=
  call :process_classpath "%CLASSPATH%"
  set CLASSPATH=%__SHORT_CLASSPATH__%
  goto :EOF

:handle_path
  set __SHORT_PATH__=
  call :process_path "%PATH%"
  set PATH=%__SHORT_PATH__%
  goto :EOF

:process_classpath
  FOR /F "TOKENS=1,* DELIMS=;" %%a IN (%1) DO (
    if NOT "%%a"=="" (
      if exist "%%a" (
        call :add_to_classpath %%~fsa
      )
    )
    if NOT "%%b"=="" (
      call :process_classpath "%%b"
    )
  )
  goto :EOF

:add_to_classpath
  if NOT "%1"=="" (
    if NOT "%__SHORT_CLASSPATH__%"=="" (
      set __SHORT_CLASSPATH__=%__SHORT_CLASSPATH__%;%1
    ) else (
      set __SHORT_CLASSPATH__=%1
    )
  )
  goto :EOF

:process_path
  FOR /F "TOKENS=1,* DELIMS=;" %%a IN (%1) DO (
    if NOT "%%a"=="" (
      if exist "%%a" (
        call :add_to_path %%~fsa
      )
    )
    if NOT "%%b"=="" (
      call :process_path "%%b"
    )
  )
  goto :EOF

:add_to_path
  if NOT "%1"=="" (
    if NOT "%__SHORT_PATH__%"=="" (
      set __SHORT_PATH__=%__SHORT_PATH__%;%1
    ) else (
      set __SHORT_PATH__=%1
    ) 
  )

命令行抛出此错误：

if NOT "" == "" (call :handle_classpath )
The syntax of the command is incorrect.

所以我尝试在自己的脚本中模拟相同的if语句：

set CLASSPATH=""

if NOT "%CLASSPATH%"=="" (
  echo "inside"
)
pause

结果是：

C:\Tools\Weblogic12\oracle_common\common\bin>if NOT """" == "" (echo "inside" )
"inside"

C:\Tools\Weblogic12\oracle_common\common\bin>pause
Press any key to continue . . .

我不知道此Weblogic发生了什么。我没有做任何事情，只是尝试测试我的应用程序，但我无法启动它。两天前它工作正常，没有任何问题。最能说明问题的是为什么Weblogic脚本中的命令行抛出错误以及我自己的相同情况都能正常工作。

Answer 1

我找到了解决方案。 Path环境变量存在问题。当我使用GUI进行检查时，以及在控制台中进行打印时，都存在差异。在控制台系统中，添加到Microsoft .net Framework的路径，该路径末尾包含引号引起问题。最重要的是，当我使用GUI将某些内容添加到Path并将其删除时，再也没有到Microsoft .net的怪异路径了，它开始正常工作...

Weblogic12-启动Admin Server引发语法错误

1 个答案: