Question

在下面的代码段中，我有两个功能完全相同（read_array和read_array2），在数组中查找项目。唯一的区别是参数的数据类型（string[], string和int[] int）。创建两个类似的函数似乎很困难。

是否可以在一个函数中以通用方式处理这两种情况？

void main () {
    /* get index of string in array */
    string[] arr = {"one", "two", "three"};
    int index = read_array(arr, "two");
    print(@"$index\n");
    secundary ();
}

void secundary () {
    /* get index of int in array */
    int[] arr = {1, 2, 3};
    int index = read_array2(arr, 2);
    print(@"$index\n");
}


public int read_array (string[] arr, string needle) {
    for (int i=0; i < arr.length; i++) {
        if(needle == arr[i]) return i;
    } return -1;
}

// write a separate function because other data type? ughh...
public int read_array2 (int[] arr, int needle) {
    for (int i=0; i < arr.length; i++) {
        if(needle == arr[i]) return i;
    } return -1;
}

Answer 1

您可以使用泛型，但在某些事情上必须要小心。

首先，您无法将值类型（即int[]）的数组传递给泛型函数，请参阅以下问题以供参考：

Vala: Passing a generic array corrupts values

第二，您需要传递某种相等性测试函数，您必须为每种类型编写一次。

这是一个有效的示例：

public delegate bool EqualFunc<T> (T l, T r);

bool str_equals (string l, string r) {
    return l == r;
}

bool int_equals (int? l, int? r) {
    return l == r; 
}

public int read_array<T> (T[] arr, T needle, EqualFunc<T> equal_func) {
    for (int i = 0; i < arr.length; i++) {
        if (equal_func (needle, arr[i])) {
            return i;
        }
    }
    return -1;
}

void main () {
    // get index of string in array
    string[] arr = {"one", "two", "three"};
    int index = read_array (arr, "two", str_equals);
    print(@"$index\n");
    secondary ();
}

void secondary () {
    // get index of int in array
    int?[] arr = {1, 2, 3};
    int index = read_array (arr, 2, int_equals);
    print(@"$index\n");
}

将值装箱成这样的可为空值非常难看，但是我不知道解决上述编译器问题的更好方法...

如果您愿意使用libgee，则可以使用也可以使用的Gee.ArrayList。

我可以使一个函数在Vala中处理多个数据类型参数吗？

1 个答案: