Excel-计算多个条件下的唯一值

Question

我对此和解决方案示例有些疑惑。有人可以为这个特定问题提供解决方案吗？一旦看到我需要的东西，它就会点击如何在其他地方使用具有不同变量的东西。各种学习障碍。谢谢。

A       B       C        D           E
First   Last    Account Transaction  Status
Frank   Tomas   101     ACH          Fraud
Dillon  Krege   105     CC-DC   
Joann   Krimble 103     ACH 
Frank   Tomas   101     Wire    
Clint   Edwards 102     ACH         Fraud
Joann   Krimble 103     CC-DC       Fraud
Joann   Krimble 103     ACH 

使用“ ACH”的交易记录（D列）并被编码为“欺诈”的状态（E列）的唯一帐户（C列）？

此表中有3000多个行，如果有区别的话。数据透视表不是一种选择，我可以很快完成。

Answer 1

使用：

=SUMPRODUCT(((D2:D8="ACH")*(E2:E8="FRAUD"))/(COUNTIFS(C:C,C2:C8,D:D,"ACH",E:E,"FRAUD")+(D2:D8<>"ACH")+(E2:E8<>"FRAUD")))

Answer 2

这与Scott Craner的响应本质上是相同的方法，但是包含了动态列长度。

=SUMPRODUCT(((D$2:INDEX(D:D, MATCH(1E+99, C:C))=H2)*(E$2:INDEX(E:E, MATCH(1E+99, C:C))=I2))/
            (COUNTIFS(C$2:INDEX(C:C, MATCH(1E+99, C:C)), C$2:INDEX(C:C, MATCH(1E+99, C:C)),
                      D$2:INDEX(D:D, MATCH(1E+99, C:C)), H2, E$2:INDEX(E:E, MATCH(1E+99, C:C)), I2)+
            (D$2:INDEX(D:D, MATCH(1E+99, C:C))<>H2)+(E$2:INDEX(E:E, MATCH(1E+99, C:C))<>I2)))

此公式的动态列长度确实取决于科目为真数字。