Question

我的问题是对this discussion的跟进。

是。遵循grabToImage的方式可以为我提供任何特定QQuickItem的快照，例如下面的parent_rect。

Rectangle {
    id: parent_rect
    width: 400
    height: 400

    Rectangle {
        id: child_rect1
        width: parent.width/4
        height: parent.height/4
    }

    Rectangle {
        id: child_rect2
        width: parent.width/4
        height: parent.height/4
    }
}
// ...
parent_rect.grabToImage(function(result) {
                       result.saveToFile("something.png");
                   });

问题：
但是，这个grabToImage也为我提供了其所有子项的快照，即child_rect1和child_rect2。

问题：
如何仅获取parent_rect的快照而不将其子级添加到返回的结果中？

Answer 1

一种可能的解决方案是隐藏子级，然后恢复可见性。

示例：

import QtQuick 2.9
import QtQuick.Window 2.2

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    function grabWithoutChildren(item, filename){
        var isVisibleList = []
        var i
        for(i in item.children){
            isVisibleList[i] = item.children[i].visible
            item.children[i].visible = false
        }

        item.grabToImage(function(result) {
            result.saveToFile(filename)
            for(i in item.children){
                 item.children[i].visible = isVisibleList[i]
            }
        })
    }

    Rectangle {
        id: parent_rect
        width: 400
        height: 400
        color: "red"

        Rectangle {
            id: child_rect1
            width: parent.width/4
            height: parent.height/4
            color: "blue"
        }

        Rectangle {
            id: child_rect2
            x: 10
            y: 10
            width: parent.width/4
            height: parent.height/4
            color: "green"

            Rectangle{
                x:50
                y:50
                width: 100
                height: 100
                color: "white"
            }
        }
    }

    Component.onCompleted: grabWithoutChildren(parent_rect, "something.png")
}

Qt：如何获取QQuickItem的快照，而不从获取的结果中删除其子级QQuickItems

1 个答案: