Question

我有一个电子表格“上载”，我运行一个宏来编译工作表上的数据。我有一列“ D”，该列将数据归因于客户端。我想寻找一个特定的客户端，并自动将这些行移动到另一个工作表。我已经尝试过此代码，但出现错误“ Upload.Range（“ D1”，Upload.Range（“ D”＆Upload.Rows.Count）“

我希望将来的客户信息也需要与初始电子表格分开。

任何帮助将不胜感激

Sub TransferData()

        Dim ar As Variant
        Dim i As Integer
        Dim lr As Long

ar = Array("3032")

Application.ScreenUpdating = False
Application.DisplayAlerts = False

  For i = 0 To UBound(ar)
         Upload.Range("D1", Upload.Range("D" & Upload.Rows.Count).End(xlUp)).AutoFilter 1, ar(i), 4, , 0
         lr = Upload.Range("D" & Rows.Count).End(xlUp).Row
         If lr > 1 Then
         Upload.Range("A2", Upload.Range("G" & Upload.Rows.Count).End(xlUp)).Copy Sheets(ar(i)).Range("A" & Rows.Count).End(3)(2)
         Upload.Range("A2", Upload.Range("G" & Upload.Rows.Count).End(xlUp)).Delete
         Sheets(ar(i)).Columns.AutoFit
         End If
    Next i
[G1].AutoFilter

Application.DisplayAlerts = True
Application.CutCopyMode = False
Application.ScreenUpdating = True
MsgBox "Data transfer completed!", vbExclamation, "Status"

End Sub

Answer 1

worksheet Name属性和worksheet Codename属性之间有很大的区别。

虽然可以更改工作表的代号，但这不是常见的做法，如果不确定，则很可能是在引用工作表的Name属性。

您的叙述中并没有说要获得“底部10个结果”，但是您的代码对xlBottom10Items运算符使用了 4 （请参见xlAutoFilterOperator enumeration ）。

我不知道Sheets(ar(i)).Range("A" & Rows.Count).End(3)(2)中的 3 是什么意思。我想您的意思是 xlUp ，其数值为 -4162 。（请参阅xlDirection enumeration）。

Sub TransferData()

    Dim ar As Variant
    Dim i As Long, lr As Long

    ar = Array("3032")

    ' ... app environment settings removed for brevity

    'reference the filter worksheet properly
    With Worksheets("Upload")
        lr = .Range("D" & Rows.Count).End(xlUp).Row
        If .AutoFilterMode Then .AutoFilterMode = False
        For i = LBound(ar) To UBound(ar)
            'there was no mention of 'bottom 10 items in your narrative but your code shows that option
            With .Range("D1:D" & lr)
                '.AutoFilter field:=1, Criteria1:=ar(i), _
                            Operator:=xlBottom10Items, VisibleDropDown:=False
                .AutoFilter field:=1, Criteria1:=(ar(i)), VisibleDropDown:=False

                With .Resize(.Rows.Count - 1, .Columns.Count).Offset(1, 0)
                    If CBool(Application.Subtotal(103, .Cells)) Then
                        .Offset(0, -3).Resize(, 7).Copy _
                          Destination:=Worksheets(ar(i)).Range("A" & Rows.Count).End(xlUp)(2)
                        Worksheets(ar(i)).Columns.AutoFit
                        .Delete shift:=xlUp
                    End If
                End With
            End With
        Next i
        If .AutoFilterMode Then .AutoFilterMode = False
    End With

    ' ... app environment settings removed for brevity

    MsgBox "Data transfer completed!", vbExclamation, "Status"

End Sub

那应该让您入门。看来您仍然可以根据我的笔记做出一些决定。

_{Application.CutCopyMode = False}

请参见Should I turn .CutCopyMode back on before exiting my sub procedure?。

根据单元格值将数据从一张纸移动到另一张纸

1 个答案: