Question

我曾经在数学上写过人类证明，但是我对写Agda很陌生。以下是一个玩具示例，说明我无法弄清楚如何使用Agda进行证明。

非正式地，我想编写一个函数f，该函数采用一个自然数x和一对自然数。如果该对中的第一个元素等于x，则返回该对中的第二个元素。否则，返回0。

这是我对自然数相等的定义：

data N : Set where
  zero : N
  s : N → N

data _≡_ {X : Set} : X → X → Set where
  refl : (x : X) → (x ≡ x)

data _≢_ : N → N → Set where
  <   : {n : N} → (zero ≢ (s n))
  >   : {n : N} → ((s n) ≢ zero)
  rec : {n m : N} → (n ≢ m) → ((s n) ≢ (s m))

data _=?_ (n m : N) : Set where
  true  : (n ≡ m) → (n =? m)
  false : (n ≢ m) → (n =? m)

equal? : (n m : N) → (n =? m)
equal? zero zero = true (refl zero)
equal? zero (s _) = false <
equal? (s _) zero = false >
equal? (s n) (s m) with (equal? n m)
... | (true (refl a)) = (true (refl (s a)))
... | (false p) = (false (rec p))

这是函数。

data Npair : Set where
  pair : (n m : N) → Npair

f : N → Npair → N
f a (pair b c) with equal? a b
... | (true (refl _)) = c
... | (false _) = zero

我无法证明

lemma : (x y : N) → (y ≡ (f x (pair x y)))

因为当我尝试在定义中引入refl构造函数时，它会抱怨

y != f x (pair x y) | equal? x x of type N

为了证明这一引理，我必须改变什么？

Answer 1

在lemma中，您需要在equal? x x上进行模式匹配，因为f也要在其上进行匹配，并且您不能推理f的输出，直到你做同样的比赛。但是，equal? x x有两种情况：

lemma : (x y : N) → (y ≡ (f x (pair x y)))
lemma x y with equal? x x 
... | true (refl _) = refl _
... | false _       = ?

在这种情况下，第二种情况是不可能的。要排除它，您需要证明∀ n → equal? n n ≡ true (refl _)：

equal?-true : ∀ n → equal? n n ≡ true (refl _)
equal?-true zero = refl _
equal?-true (s n) with equal? n n | equal?-true n
... | true (refl _) | q = refl _
... | false x       | ()

lemma : (x y : N) → (y ≡ (f x (pair x y)))
lemma x y with equal? x x | equal?-true x
... | true (refl _) | _ = refl _
... | false _       | ()

但是，如果您将不平等定义为等于否定，则不需要做额外的工作，因为x ≢ x会立即暗示⊥。

data ⊥ : Set where

⊥-elim : ⊥ → {A : Set} → A
⊥-elim ()

_≢_ = λ {A : Set}(x y : A) → x ≡ y → ⊥

data _=?_ (n m : N) : Set where
  true  : (n ≡ m) → (n =? m)
  false : (n ≢ m) → (n =? m)

equal? : ∀ n m → n =? m
equal? zero zero   = true (refl zero)
equal? zero (s m)  = false (λ ())
equal? (s n) zero  = false (λ ())
equal? (s n) (s m) with equal? n m
... | true  (refl _) = true (refl _)
... | false p        = false λ {(refl _) → p (refl n)}

data Npair : Set where
  pair : (n m : N) → Npair

f : N → Npair → N
f a (pair b c) with equal? a b
... | (true (refl _)) = c
... | (false _)       = zero

lemma : (x y : N) → (y ≡ (f x (pair x y)))
lemma x y with equal? x x
... | true (refl .x) = refl y
... | false p        = ⊥-elim (p (refl _))

我怎样才能说服阿格达我的职能具有一定的价值？

1 个答案: