Question

我有一个用elixir / phoenix制作的Web应用程序。我将围绕标题继续我的解释。因此，我在系统中有一个名为roles的东西，还有一个名为permissions的东西。

roles通过中间表many-to-many与permissions具有role_permissions关系。

这三个的模式大致相同：

角色

schema "roles" do
    # associations
    has_many(:users, User)
    many_to_many(:permissions, Permission, join_through: "role_permissions")

    field(:name, :string)
    field(:description, :string)

    timestamps()
  end 

@required_params ~w(name)a
@optional_params ~w(description)a
@create_params @required_params ++ @optional_params
@update_params @required_params ++ @optional_params

@doc """
Returns a changeset to create a new `role`.
"""
@spec create_changeset(t, map) :: Ecto.Changeset.t()
def create_changeset(%__MODULE__{} = role, params) do
 role
 |> cast(params, @create_params)
 |> common_changeset()
end

权限

schema "permissions" do
    field(:code, :string)
    field(:description, :string)

    timestamps()
  end

角色权限

 schema "permissions" do
    belongs_to(:role, Role)
    belongs_to(:permission, Permission)

    timestamps()
  end

permissions可以与角色分开创建，因此我具有创建它们的CRUD函数。

但是，在创建roles时，它们应该与permissions关联。为此，我使用了如下所示的create函数

def create(%{permissions: permissions} = params) when permissions != [] do
    Multi.new()
    |> Multi.run(:role, fn _ ->
      QH.create(Role, params, Repo)
    end)
    |> permissions_multi(params)
    |> persist()
  end

defp permissions_multi(multi, params) do
    Multi.run(multi, :permission, fn %{role: role} ->
      role_permissions = associate_role_permissions(role, params[:permissions])
      {count, _} = Repo.insert_all(RolePermission, role_permissions)
      {:ok, count}
    end)
  end

  defp associate_role_permissions(role, permissions) do
    Enum.map(permissions, fn permission ->
      [permission_id: permission,
      role_id: role.id,
      inserted_at: DateTime.utc_now,
      updated_at: DateTime.utc_now]
    end)
  end

  # Run the accumulated multi struct
  defp persist(multi) do
    case Repo.transaction(multi) do
      {:ok, %{role: role}} ->
        {:ok, role}

      {:error, _, _, _} = error ->
        error
    end
  end

create/1包含name，description和permissions，这是 permission_ids 的列表。

角色首先插入数据库。插入后，我收到{:ok, role} 我使用associate_role_permission将role_id与所有权限ID配对，并使用Repo.insert_all在中间表中进行插入。

所有这些都很好，我已经为此编写了测试，并且有效。

当我使用phoenix进入UI时出现问题。

控制器

def new(conn, _params) do
  changeset = RoleSchema.create_changeset(%RoleSchema{}, %{permissions: nil})
  render(conn, "new.html", changeset: changeset)
end

“ new.html”如下：

<%= form_for @changeset, @action, [as: :role], fn f -> %>
  <%= input f, :name %>
  <%= input f, :description %>
  <%= multiple_select(f, :permissions, formatted_list(:permissions))%>
  <%= submit "Submit", class: "btn btn-primary submit-btn" %>
  <%= link("Cancel", to: role_path(@conn, :index), class: "btn btn-primary") %>
<% end %>

我要在此处执行的操作是从下拉列表中为多选创建下拉菜单我正在以[{：code，：id}]格式加载权限列表，效果很好。

但是我不断收到错误

protocol Phoenix.HTML.Safe not implemented for #Ecto.Association.NotLoaded<association :permissions is not loaded>.

我知道错误是因为在变更集中数据字段具有权限未加载。

该问题的解决方法是什么？

是否有一种方法可以修改changeset.data字段中的特定字段，这是否是正确的方法？

Answer 1

您必须明确Ecto.Query.preload/3每个关联，Ecto不会默默进行。您的RoleSchema在:permissions中有一个关联，并且由于它没有预先加载在新创建的变更集中，因此它返回Ecto.Association.NotLoaded结构，该结构暂时替换了实际值，直到加载了关联。

由于您在此处创建 changeset，因此只需显式更新其数据，例如：

changeset = RoleSchema.create_changeset(%RoleSchema{})
changeset = update_in(changeset.data, &Repo.preload(&1, :permissions))
...

处理凤凰中已存在的表之间的多对多关系

1 个答案: