Question

我有像这样的JSON结构

{
  "Items": {
     "Apple": {
       "Type": 2,
       "keyVal": "6044e3a3-c064-4171-927c-2440e2f65660"
     },
     "Lemons": {
       "Type": 1,
       "keyVal": "79c45f4d-4f62-4c8e-8de1-79e04fc9b95d"
     }
  },
  "Species": 0,
  "Name": "Test Fruit",
  "Description": "Test Des",
  "Creator": "xyz",
  "SKey" : "123"
}

这存在于名为Fruits的集合中。

查询：我正在尝试编写AQL查询以查找其中Item中的KeyVal值为某个值的SKey。

我传统上习惯于SQL语法，但这是我第一次冒险进入AQL（Arango DB）。

任何有关语法的帮助都是适用的

Answer 1

这里解释了AQL的基础知识：https://docs.arangodb.com/3.3/AQL/index.html

FOR item IN Items FILTER item.keyVal == "someValue" RETURN item

将是您的最小SQL SELECT ... WHERE语句。

BTW：这里有一个比较性的介绍：
https://arangodb.com/why-arangodb/sql-aql-comparison/

学习AQL的一个好方法是尝试使用小块代码返回结果进行检查，逐步创建更复杂的查询。

例如，让我们返回一个嵌套的keyVal值：

FOR doc IN Fruits
  RETURN doc.Items.Apple.keyVal
  // "6044e3a3-c064-4171-927c-2440e2f65660"

要按Apple keyVal过滤并返回SKey，您可以执行以下操作：

FOR doc IN Fruits
  FILTER doc.Items.Apple.keyVal == "6044e3a3-c064-4171-927c-2440e2f65660"
  RETURN doc.SKey
  // "123"

您也可以返回两个keyVal值：

FOR doc IN Fruits
  RETURN [
    doc.Items.Apple.keyVal,
    doc.Items.Lemons.keyVal
  ]
  // [
  //   "6044e3a3-c064-4171-927c-2440e2f65660",
  //   "79c45f4d-4f62-4c8e-8de1-79e04fc9b95d"
  // ]

如果任何一个等于某个值，要返回SKey，请尝试：

FOR doc IN Fruits
  FILTER "79c45f4d-4f62-4c8e-8de1-79e04fc9b95d" IN [
    doc.Items.Apple.keyVal,
    doc.Items.Lemons.keyVal
  ]
  RETURN doc.SKey

注意：IN在这里用作数组运算符，就像{array}中包含的{value}一样。

要返回硬编码属性路径的所有keyVal值，您可以使用ATTRIBUTES() AQL function：

FOR doc IN Fruits
  FOR attr IN ATTRIBUTES(doc.Items)
    RETURN doc.Items[attr].keyVal

如果任何嵌套的keyVal值匹配，要返回SKey，我们可以这样做：

FOR doc IN Fruits
  LET keyVals = (FOR attr IN ATTRIBUTES(doc.Items)
    RETURN doc.Items[attr].keyVal
  )
  FILTER "6044e3a3-c064-4171-927c-2440e2f65660" IN keyVals
  RETURN doc.SKey

注意：这使用子查询来捕获中间结果。

要测试是否包含所有指定值，您可以执行以下操作：

LET ids = [
  "79c45f4d-4f62-4c8e-8de1-79e04fc9b95d",
  "6044e3a3-c064-4171-927c-2440e2f65660"
]
FOR doc IN Fruits
  LET keyVals = (FOR attr IN ATTRIBUTES(doc.Items)
    RETURN doc.Items[attr].keyVal
  )
  FILTER ids ALL IN keyVals
  RETURN doc.SKey

ALL IN是一个数组比较运算符。

请注意，如果您想在不对属性路径进行硬编码的情况下使用索引以及不同的查询，则需要更改数据模型。

查询以下JSON结构所需的AQL语法

1 个答案: