Question

我有一个包含此页面的页面：

<a href="http://www.trial.com" title="yellow">Trial</a>
<a href="http://www.trial1.com" title="red">Trial2</a>

如何获取锚文本，网址和标题？

我想要输出：

Trial, http://www.trial.com, yellow
Trial2, http://www.trial1.com, red

我尝试将WWW::Mechanize用作explained also here，但我不知道如何以这种方式获得标题。你有什么想法吗？

Answer 1

简单版本，基于您的问题

一个看起来像你的页面（所以没有任何模糊的HTML可以搞砸）
te所需的输出

这可能就是你要找的东西：

use strict;
use warnings;

use WWW::Mechanize;

my $mech = WWW::Mechanize->new;
$mech->get('file:page.html');

foreach my $link ($mech->links) {
    my $text  = $link->text;
    my $url   = $link->url;
    my $title = $link->attrs->{title};

    print "$text, $url, $title\n"
}

快乐编码，TIMTOWTDI

Answer 2

使用问题中提供的文档。我创造了一些能够解决你的问题的东西。显然使用https://www.perlmonks.org有一些异常值，因为有些网址不是完整的网址，但如果不是您想要的话，可以通过一些简单的检查和跳过，我认为您可以得到您想要的内容。

示例输出：

_____________________________________________________________________________________________________________________________
| Text                                            | URL                | Attributes
_____________________________________________________________________________________________________________________________
| Testing a metacpan dist with XS components      | ?node_id=1216149   | [name]post-head-id1216149[id]post-head-id1216149,  |
| Controlling the count in array                  | ?node_id=1216134   | [name]post-head-id1216134[id]post-head-id1216134,  |

很可能你被困在了hashref上。您只需要创建一个for循环来遍历那些以获取属性标记及其值。

代码：

#!/usr/bin/perl
# your code goes here
use strict;
use warnings;
use Data::Dumper;
use WWW::Mechanize ();
$ENV{'PERL_LWP_SSL_VERIFY_HOSTNAME'} = 0;

my @urls = (
    q{https://www.perlmonks.org/}
);

my $mech = WWW::Mechanize->new();
$mech->get(@urls);

my @links = $mech->links();
print qq{______________________________________________________________________________________________________________\n};
printf(qq{| %-65s | %-75s | %-25s\n},q{Text},q{URL},q{Attributes});
print qq{______________________________________________________________________________________________________________\n};
foreach my $link (@links) {
    if ($link->text() && $link->url()) {
        my $a;
        foreach my $attr (keys %{$link->attrs()}) {
            next if $attr =~ m/href/i;

            #$link->attr()->{$attr} is the value of the key in this hashref. 
            $a .= qq{[$attr]} . $link->attrs()->{$attr};
        }
        my $info;
        if ($a) {
            $info = sprintf(qq{| %-65s | %-75s | %-25s, },$link->text(),$link->url(),$a);
        } else {
            $info = sprintf(qq{| %-65s | %-75s |},$link->text(),$link->url());
        }
        print $info . qq{ |\n};
    }
}

如何在Perl中从HTML中提取URL标记和链接文本？

2 个答案: