如何检索cl.exe的路径？

Question

我想在Visual Studio中检索编译器cl.exe的完整路径，以便从程序中调用它。我们在注册表中是否有密钥？怎么做？

Answer 1

cl.exe通常位于%VCINSTALLDIR%\bin\。默认情况下未设置VCINSTALLDIR环境变量，但在打开Visual Studio的本机工具命令提示符时会设置它。

以下是该批处理脚本的完成方式：

:GetVCInstallDir
@set VCINSTALLDIR=
@call :GetVCInstallDirHelper32 HKLM > nul 2>&1
@if errorlevel 1 call :GetVCInstallDirHelper32 HKCU > nul 2>&1
@if errorlevel 1 call :GetVCInstallDirHelper64  HKLM > nul 2>&1
@if errorlevel 1 call :GetVCInstallDirHelper64  HKCU > nul 2>&1
@exit /B 0

:GetVCInstallDirHelper32
@for /F "tokens=1,2*" %%i in ('reg query "%1\SOFTWARE\Microsoft\VisualStudio\SxS\VC7" /v "14.0"') DO (
    @if "%%i"=="14.0" (
        @SET VCINSTALLDIR=%%k
    )
)
@if "%VCINSTALLDIR%"=="" exit /B 1
@exit /B 0

:GetVCInstallDirHelper64
@for /F "tokens=1,2*" %%i in ('reg query "%1\SOFTWARE\Wow6432Node\Microsoft\VisualStudio\SxS\VC7" /v "14.0"') DO (
    @if "%%i"=="14.0" (
        @SET VCINSTALLDIR=%%k
    )
)
@if "%VCINSTALLDIR%"=="" exit /B 1
@exit /B 0

因此，根据系统的位数，它会查看其中一个注册表项

32位

如果系统范围内安装了VS，则
1. HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\VisualStudio\SxS\VC7
2. HKEY_CURRENT_USER\SOFTWARE\Microsoft\VisualStudio\SxS\VC7如果为当前用户安装了VS

64位

如果系统范围内安装了VS，则
1. HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\VisualStudio\SxS\VC7
2. HKEY_CURRENT_USER\SOFTWARE\Wow6432Node\Microsoft\VisualStudio\SxS\VC7如果为当前用户安装了VS

然后，每个已安装的版本都有字符串。这就是它在我的机器上的样子：



如果您不知道自己想要的版本，则需要额外的工作来以编程方式检索正确的值，但这超出了此问题的范围。

Answer 2

我建议使用MS自己的工具来定位cl.exe。我过去曾经使用过它，它也可以用于新版本的VisualStudio。

参考：https://github.com/Microsoft/vswhere