Question

我有一个抽象类型和几个继承自他的类型。现在我需要创建一些继承类型的实例数组，但我不确定，如果它甚至可以在Fortran中使用。

我尝试制作一些包装类型，例如Creating heterogeneous arrays in Fortran。

module m
implicit none

type, abstract :: a
    integer, public :: num 
end type a

type, extends(a) :: b
end type b

type, extends(a) :: c
end type c

type :: container
    class(*), allocatable :: ptr 
end type
end module m

program mwe 
use m

type(b) :: b_obj
class(*), allocatable :: a_arr(:)

b_obj = b(1)

allocate(container :: a_arr(3))
a_arr(1) = container(b_obj)

end program mwe

但是我收到了这个错误：

test3.f90:28:25:

 a_arr(1) = container(b_obj)
                     1
Error: Can't convert TYPE(b) to CLASS(*) at (1)

我做错了什么？或者还有其他正确的方法吗？

尝试2

我根据francescalus的回答编辑了代码：

program mwe 
use m

type(b) :: b_obj
type(c) :: c_obj
type(container), allocatable :: a_arr(:)
integer :: i

b_obj = b(1)
c_obj = c(2)

allocate(container :: a_arr(3))
a_arr(1)%ptr = b(1)
a_arr(2)%ptr = c(3)
a_arr(3)%ptr = c(1000)

do i=1,3
    write(*,*) a_arr(i)%ptr%num
end do

end program mwe

我又收到了另一个错误：

test3.f90:36:35:

     write(*,*) a_arr(i)%ptr%num
                               1
Error: ‘num’ at (1) is not a member of the ‘__class__STAR_a’ structure

Answer 1

正如IanH commented在概述您采用的方法时，当时的gfortran版本

似乎不支持通过结构构造函数定义无限多态组件

container(b_obj)就是这样。所以，不管你是否仍然遇到这个问题，人们可能仍然希望允许旧版本/其他编译器使用该代码。

另一种方法是不要对容器的元素使用构造函数。相反，单个组件可以直接在赋值中使用：

use m
type(container) a_arr(3)  ! Not polymorphic...
a_arr%ptr = b(1)          ! ... so it has component ptr in its declared type
end mwe

当然，我们仍然拥有容器类型多态的组件，因此任何尝试引用/定义/等等，该组件都将受到各种限制。在你的问题中，你有无限多态的组件，但我看到你首先谈到限制容器对扩展第一种类型的元素的考虑。不是将容器组件声明为无限多态，而是声明类型a可能更有帮助：

type :: container
    class(a), allocatable :: ptr 
end type

这足以解决

的问题

do i=1,3
    write(*,*) a_arr(i)%ptr%num
end do

因为num是声明类型a_arr(i)%ptr的组件（即。a）。一般来说，它不是完整的解决方案，因为

do i=1,3
    write(*,*) a_arr(i)%ptr%num_of_type_b
end do

不会工作（扩展类型中有num_of_type_b个组件）。在这里你必须使用通常的技巧（定义的输入/输出，动态分辨率，select type等）。这些超出了这个答案的范围，并且可以找到许多其他问题。

Answer 2

我添加了更正以解决以下错误，

test3.f90:36:35:

     write(*,*) a_arr(i)%ptr%num
                               1
Error: ‘num’ at (1) is not a member of the ‘__class__STAR_a’ structure

无限多态变量不能直接访问动态数据类型的任何组件。在这种情况下，一种简单的解决方案是避免使用class(*)。 container的定义更改为

type :: container
    class(a), allocatable :: ptr 
end type

因此，总结中的工作代码如下，

module m

  implicit none

  type, abstract :: a
    integer, public :: num 
  end type a

  type, extends(a) :: b
  end type b

  type, extends(a) :: c
  end type c

  type :: container
    class(a), allocatable :: ptr 
  end type

end module m

program mwe

  use m

  type(container), allocatable :: a_arr(:)
  integer :: i

  allocate(container :: a_arr(3))
  a_arr(1)%ptr = b(1)
  a_arr(2)%ptr = c(3)
  a_arr(3)%ptr = c(1000)

  do i=1,3
      write(*,*) a_arr(i)%ptr%num
  end do

end program mwe

Fortran类的异构数组

尝试2

2 个答案: