Question

我试图解析JSON-LD，其中一个可能的构造是

"John" : { 
  "type": "person",
  "friend": [ "Bob", "Jane" ],
}

我想解码为

类型的记录

type alias Triple = 
  { subject: String, predicate: String, object: String }

所以上面的例子变成了：

Triple "John" "type" "person"
Triple "John" "friend" "Bob"
Triple "John" "friend" "Jane"

但是＆＃34;朋友＆＃34;在JSON对象中也可以只是一个字符串：

"friend": "Mary"

在这种情况下，相应的三元组将是

Triple "John" "friend" "Mary"

有什么想法吗？

Answer 1

首先，您需要一种方法来列出JSON对象中的所有键/值对。 Elm为此目的提供Json.Decode.keyValuePairs功能。它为您提供了一个用于predicate字段的密钥名称列表，但您还必须描述一个解码器，以便将其用于值。

由于您的值是字符串或字符串列表，因此您可以使用Json.Decode.oneOf来提供帮助。在此示例中，我们只是将字符串转换为单个列表（例如"foo"变为["foo"]），因为它可以让以后更容易映射。

stringListOrSingletonDecoder : Decoder (List String)
stringListOrSingletonDecoder =
    JD.oneOf
        [ JD.string |> JD.map (\s -> [ s ])
        , JD.list JD.string
        ]

由于keyValuePairs的输出将是(String, List String)值的列表，因此我们需要一种方法将这些值展平为List (String, String)值。我们可以像这样定义这个函数：

flattenSnd : ( a, List b ) -> List ( a, b )
flattenSnd ( key, vals ) =
    List.map (\val -> ( key, val )) vals

现在您可以使用这两个功能将对象拆分为三元组。这接受一个字符串参数，这是查询调用函数的关键（例如，我们需要查找包装"John"键）。

itemDecoder : String -> Decoder (List Triple)
itemDecoder key =
    JD.field key (JD.keyValuePairs stringListOrSingletonDecoder)
        |> JD.map
            (List.map flattenSnd
                >> List.concat
                >> List.map (\( a, b ) -> Triple key a b)
            )

See a working example here on Ellie

请注意，键的顺序可能与您在输入JSON中列出它们的方式不匹配，但这就是JSON的工作原理。它是一个查找表，而不是一个有序列表

在json中解码事物或事物列表

1 个答案: