如何生成汇总统计表

Question

我想生成一个如下所示的摘要统计表：

       Female    Male
p1
p10
p50 
p99 

但是，对于estpost和esttab，我只能生成如下表格：

        (1)         (2)
      p1/p10/p5~99  p1/p10/p5~99
       -3.756124    -4.159476
        1.009338    -1.210738
        .3221763    .2945236
        .8658271    .8658271
        .9871135    .9871135

我使用的代码如下：

estpost summarize math_std if female == 1 , detail
eststo  female

estpost summarize math_std if female == 0 , detail
eststo  male

esttab female male , cells(p1 p10 p50 p95 p99) noobs

如何将列标签放在所需的位置？

Answer 1

这是一个依赖于创建具有相关结果的矩阵的解决方案：

sysuse auto, clear

quietly summarize price if foreign == 1 , detail
matrix foreign = r(p1) \ r(p10) \ r(p50) \ r(p95) \ r(p99)

quietly summarize price if foreign == 0 , detail
matrix domestic = r(p1) \ r(p10) \ r(p50) \ r(p95) \ r(p99)

matrix both = foreign , domestic
matrix rownames both = p1 p10 p50 p95 p99
matrix colnames both = foreign domestic

esttab matrix(both), mlabels(none)

--------------------------------------            
                  foreign     domestic
--------------------------------------
p1                   3748         3291
p10                  3895         3955
p50                  5759       4782.5
p95                 11995        13594
p99                 12990        15906
--------------------------------------