Question

我第一次使用deftype是因为我正在编写优先级队列，而defrecord正在干扰实施ISeq。

为了避免需要"deconstruct" the class, alter a field, and "reconstruct" it via explicit calls to it's constructor constantly，我发现自己需要为update所需的每个字段编写alter - 类似函数：

(deftype Priority-Queue [root size priority-comparator])

(defn- alter-size [^Priority-Queue queue, f]
  (->Priority-Queue (.root queue) (f (.size queue)) (.priority_comparator queue)))

(defn- alter-root [^Priority-Queue queue, f]
  (->Priority-Queue (f (.root queue)) (.size queue) (.priority_comparator queue)))

当然，我可以编写一个函数来允许语法更接近update，但对此的需求似乎有点气味。

这是改变非记录的典型方法吗？我在其他地方尽可能多地提取，所以我需要实际改变队列本身的次数仅限于几个地方，但它仍然感觉很笨重。是编写类似于Scala's copy for case classes的函数/宏的唯一干净解决方案吗？

Answer 1

我建议为此制作一些宏。我最后得到了这个：

(defmacro attach-updater [deftype-form]
  (let [T (second deftype-form)
        argnames (nth deftype-form 2)
        self (gensym "self")
        k (gensym "k")
        f (gensym "f")
        args (gensym "args")]
    `(do ~deftype-form
         (defn ~(symbol (str "update-" T))
           ^{:tag ~T} [^{:tag ~T} ~self ~k ~f & ~args]
           (new ~T ~@(map (fn [arg]
                            (let [k-arg (keyword arg)]
                              `(if (= ~k ~k-arg)
                                 (apply ~f (. ~self ~arg) ~args)
                                 (. ~self ~arg))))
                          argnames))))))

它只是处理deftype表单的arg列表，并创建函数update-%TypeName%，它具有与简单update类似的语义，使用字段名称的关键字变体，并返回对象的克隆，改变了领域。

快速示例：

(attach-updater
 (deftype MyType [a b c]))

扩展为以下内容：

(do
  (deftype MyType [a b c])
  (defn update-MyType [self14653 k14654 f14655 & args14656]
    (new
      MyType
      (if (= k14654 :a)
        (apply f14655 (. self14653 a) args14656)
        (. self14653 a))
      (if (= k14654 :b)
        (apply f14655 (. self14653 b) args14656)
        (. self14653 b))
      (if (= k14654 :c)
        (apply f14655 (. self14653 c) args14656)
        (. self14653 c)))))

可以像这样使用：

(-> (MyType. 1 2 3)
    (update-MyType :a inc)
    (update-MyType :b + 10 20 30)
    ((fn [item] [(.a item) (.b item) (.c item)])))
;;=> [2 62 3]

(attach-updater
  (deftype SomeType [data]))

(-> (SomeType. {:a 10 :b 20})
    (update-SomeType :data assoc :x 1 :y 2 :z 3)
    (.data))
;;=> {:a 10, :b 20, :x 1, :y 2, :z 3}

你还可以避免为每种类型生成update-%TypeName%函数，使用协议（比如Reconstruct）并在宏中自动实现它，但是这会让你失去使用varargs的可能性，因为它们是不支持协议功能（例如，您无法做到这一点：(update-SomeType :data assoc :a 10 :b 20 :c 30)）

<强>更新

我还有一种方法可以避免在这里使用宏。虽然它是一个骗子（因为它使用->Type构造函数的元数据），也可能慢（因为它也使用反射）。但它仍然有效：

(defn make-updater [T constructor-fn]
  (let [arg-names (-> constructor-fn meta :arglists first)]
    (fn [self k f & args]
      (apply constructor-fn
             (map (fn [arg-name]
                    (let [v (-> T (.getField (name arg-name)) (.get self))]
                      (if (= (keyword (name arg-name))
                             k)
                        (apply f v args)
                        v)))
                  arg-names)))))

它可以像这样使用：

user> (deftype TypeX [a b c])
;;=> user.TypeX

user> (def upd-typex (make-updater TypeX #'->TypeX))
;;=> #'user/upd-typex

user> (-> (TypeX. 1 2 3)
          (upd-typex :a inc)
          (upd-typex :b + 10 20 30)
          (#(vector (.a %) (.b %) (.c %))))
;;=> [2 62 3]

干净地更新deftype＆quot;类的字段

1 个答案: