Question

我有一个xml。我正在使用xsl样式表对其进行转换，并使用java在html页面中显示。我的要求是，我需要比较两个节点值，如果存在差异，我需要突出显示已更改的字符值。如何才能做到这一点？

XML：

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<Message> 
<DiffDetailMessage>
    <TestCaseID>000001</TestCaseID>     
    <res1>VI7002 1D</res1>
    <res2>VI7002 DD </res2>
</DiffDetailMessage>
<DiffDetailMessage>
    <TestCaseID>000002</TestCaseID>
    <res1>BS7002 1D</res1>
    <res2>BS7002 SS  </res2>
</DiffDetailMessage>
</Message>

XSL：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html>
<body>
<h2>Report</h2>  
<xsl:apply-templates/> 
</body>
</html>
</xsl:template>

<xsl:template match="Message/DiffDetailMessage">
<table border="2">  
<xsl:apply-templates select="TestCaseID"/>  
<xsl:apply-templates select="res1"/>
<xsl:apply-templates select="res2"/>    
</table>
</xsl:template>

<xsl:template match="TestCaseID">
<tr><td><b>Test CaseID </b></td> 
<td><xsl:value-of select="."/></td></tr>
</xsl:template>

<xsl:template match="res1">
<tr><td><b>Res1</b></td>
<td><xsl:value-of select="."/> </td> </tr>
</xsl:template>

<xsl:template match="res2">
<tr><td><b>Res2</b></td>
<td><xsl:value-of select="."/></td> </tr>
</xsl:template>
</xsl:stylesheet>

如何将节点值res1与res2进行比较？在我的例子中，“VI70002 ID”的值应与“VI7002 DD”进行比较，因为有变化，我应该使用xsl在html页面中突出显示“D”字符。有人可以帮助这方面。

Answer 1

如果您只使用XSLT-1.0，则可以使用递归命名模板迭代字符串char-by-char：以下模板将两个字符串作为输入并放置粗体重点在每个不同的char上。如果第二个字符串比第一个字符串长，则这些尾随字符也会突出显示。

<xsl:template name="cmp">
  <xsl:param name="str1" />
  <xsl:param name="str2" />
  <xsl:choose>
    <xsl:when test="substring($str1,1,1) = substring($str2,1,1)">
      <xsl:value-of select="substring($str2,1,1)"/>
    </xsl:when>
    <xsl:when test="substring($str1,1,1) != substring($str2,1,1)">
      <b><xsl:value-of select="substring($str2,1,1)"/></b>
    </xsl:when>
    <xsl:when test="$str1 = '' and substring($str2,1,1)">
      <b><xsl:value-of select="substring($str2,1,1)"/></b>
    </xsl:when>
  </xsl:choose>
  <xsl:if test="string-length($str1) > 0 or string-length($str2) > 0">
    <xsl:call-template name="cmp">
      <xsl:with-param name="str1" select="substring($str1,2)" />
      <xsl:with-param name="str2" select="substring($str2,2)" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>

从其他模板中调用此模板以获得（部分）突出显示的＆＃34;字符串＆＃34;，例如

<xsl:template match="res2">
<tr><td><b>Res2</b></td>
<td>
    <xsl:call-template name="cmp">
        <xsl:with-param name="str1" select="../res1" />
        <xsl:with-param name="str2" select="." />
    </xsl:call-template>
</td> </tr>
</xsl:template>

比较xsl中的xml节点值并突出显示差异

1 个答案: