Question

我正在Netlogo中使用基于代理的模型组合并重写一些系统动力学模型（即库存和流动模型）。

系统动力学模型通常包括用于描述非线性关系的表函数。如果我们有两个连续变量x和y，并且我们知道近似关系是（x = 0，y = 100; x = 1，y = 50; x = 2，y = 45，x = 3，y = 40 ; x = 4，y = 35），我们可以使用插值来找到任意x值的y值。例如，在R中，您可以使用appoxfun（）函数。

在没有真正了解因果机制并在模型中编码的情况下，是否存在解决Netlogo中这些关系的方法？我一直在寻找互联网资源，但一直找不到多少。

感谢您的帮助！

Answer 1

没有现有的功能。但是，构造一个可以调用的插值函数很简单。此版本执行线性插值，并通过报告适当的结束y值来处理指定x值范围之外的值。在list函数中比我更好的人（例如reduce）可能会找到一种更优雅的方法。

to-report calc-piecewise [#xval #xList #yList]
  if not (length #xList = length #ylist)
  [ report "ERROR: mismatched points"
  ]
  if #xval <= first #xList [ report first #yList ]
  if #xval >= last #xList [ report last #yList ]
  ; iterate through x values to find first that is larger than input x
  let ii 0
  while [item ii #xlist <= #xval] [ set ii ii + 1 ]
  ; get the xy values bracketing the input x
  let xlow item (ii - 1) #xlist
  let xhigh item ii #xlist
  let ylow item (ii - 1) #ylist
  let yhigh item ii #ylist
  ; interpolate
  report ylow + ( (#xval - xlow) / (xhigh - xlow) ) * ( yhigh - ylow )  
end

to testme
  let xs [0 1 2 3 4]
  let ys [100 50 30 20 15]
  print calc-piecewise 1.5 xs ys
end

此版本要求您在每次使用时指定x值列表和y值列表（以及插值的x值）。如果你总是要使用相同的点，可以在函数内指定它们。

Netlogo中的表函数/插值

1 个答案: