Question

我试图理解XSLT如何迭代多个元素并从这些元素及其年长和年幼的兄弟姐妹中输出数据。请参阅以下示例：

<a>
    <b name="first">
        <c value="C Value">C Text</c>
        <d>D1 Text</d>
        <d>D2 Text</d>
        <e>E Text</e>
    </b>
    <b name="second">
        <c value="C Value">C Text</c>
        <d>D1 Text</d>
        <d>D2 Text</d>
        <d>D3 Text</d>
        <e>E Text</e>
    </b>
    <b name="third">
        <c value="C Value">C Text</c>
        <e>E Text</e>
    </b>
</a>

我希望输出如下（假设为了简单起见，每个元素的文本都不包含逗号）。

first,C Value,C Text,D1 Text,E Text
first,C Value,C Text,D2 Text,E Text
second,C Value,C Text,D1 Text,E Text
second,C Value,C Text,D2 Text,E Text
second,C Value,C Text,D3 Text,E Text
third,C Value,C Text,,E Text

因此可能存在任意数量的<d>元素（或根本没有）。每个CSV行必须包含来自<c>（<d>的较老兄弟）的信息，来自<d>的一个实例的信息，以及来自<e>的信息，即年轻的兄弟姐妹<d>。（我可能正在构思这个年龄越来越大的概念，但似乎有道理。）

之前我还没有使用过XSLT，所以我真的不知道从哪里开始。我发现用于迭代元素的示例并不清楚我如何从文档后面提取值（例如示例中的<e>）并返回到元素的另一个实例（例如{{ 1}}）。我用Python编写了一个带有lxml的Python实现，但是想看看XSLT是否更适合这种转换。

修改我刚刚看到一个答案被张贴，我将详细研究以试图理解它。但是，为了分享我一直在努力的事情，这里是我一直在开发的XSL。当没有<d>值时，它无法输出任何内容。

<d>

输出：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output method="text" encoding="iso-8859-1" />
    <xsl:strip-space elements="*" />

    <xsl:template match="a">       
        <xsl:for-each select="b">
            <xsl:call-template name="match-b"/>
        </xsl:for-each>
        <xsl:text>&#10;</xsl:text>
    </xsl:template>

    <xsl:template name="match-b" match="b">
        <xsl:for-each select="d">
            <xsl:value-of select="../@name"/>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="../c/@value"/>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="../c"/>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="."/>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="../e"/>
            <xsl:text>&#10;</xsl:text>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

Answer 1

您可以使用XPath导航到兄弟节点或父节点之前或之后。要使用XSLT 2或更高版本输出一行，您可以使用xsl:value-of select="expression-to-compute-column-values" separator=","，如

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0">

  <xsl:output method="text"/>

  <xsl:mode name="add-dummy-d" on-no-match="shallow-copy"/>

  <xsl:variable name="normalized-input">
      <xsl:apply-templates mode="add-dummy-d"/>
  </xsl:variable>

  <xsl:template match="b[not(d)]/c" mode="add-dummy-d">
      <xsl:next-match/>
      <d/>
  </xsl:template>

  <xsl:template match="/">
      <xsl:apply-templates select="$normalized-input/a/b/d"/>
  </xsl:template>

  <xsl:template match="d">
      <xsl:value-of select="../@name, preceding-sibling::c/(@value, .), ., following-sibling::e" separator=","/>
      <xsl:text>&#10;</xsl:text>
  </xsl:template>

</xsl:stylesheet>

如评论中所述，需要为那些不具备d的{{1}}添加空b的中间步骤，或者至少有一种方法可以确保您获得最后一行样本输出。

https://xsltfiddle.liberty-development.net/eiZQaF7的在线示例。

使用XSLT将多元素XML转换为CSV

1 个答案: