简介

Question

我有一个列表框。我使用以下文件填充文件：

for N := 0 til Listbox1.Items.Count -1 DO
   BEGIN
      NUM := ScanForNotNumberInListbox1Item(Listbox1.Items[N]);
      // 
      // returns NUM = -1 if non digit is met..
      //    
      IF NUM <> 0 then      
         begin
            LISTBOX1.Items[N].BackGroundColor := RED;
            Exit;  (* or terminate *)
         END;
  END;

加载的文件包含数字和数字（我假设）。是100 pct。当然，我现在开始扫描:(伪代码:)

    <input type="text" name="timepicker" id="timepicker" >
    <form id = "order-form" action="confirmation.php" method="POST" >
     <input class = "formitem" type="hidden" id="time" name="time" value="">
     <input class = "formitem" id="next" type="submit" value="Next">

我知道我必须使用LIstbox1.DrawItem（）;并且已经尝试了几个在Stack Exchange中显示的示例，但是所使用的示例似乎都不是代码生成的。

那我怎么能这样做呢？

克里斯

Answer 1

简介

您可以在其关联的＆＃34;对象＆＃34;中存储有关每个列表项的其他信息。这可以是（指向一个）真实对象的指针，或者您可以使用此指针大小的整数来编码您想要的任何简单信息。

举个简单的例子，让我们将项目的背景颜色放在这个字段中（uses Math）：

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;
begin

  ListBox1.Items.BeginUpdate;
  try
    ListBox1.Clear;
    for i := 1 to 100 do
      ListBox1.Items.AddObject(i.ToString, TObject(IfThen(Odd(i), clSkyBlue, clMoneyGreen)));
  finally
    ListBox1.Items.EndUpdate;
  end;

end;

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
var
  ListBox: TListBox;
  Canvas: TCanvas;
  S: string;
begin
  ListBox := Control as TListBox;
  Canvas := ListBox.Canvas;

  Canvas.Brush.Color := TColor(ListBox.Items.Objects[Index]);
  Canvas.FillRect(Rect);
  S := ListBox.Items[Index];
  Canvas.TextRect(Rect, S, [tfSingleLine, tfVerticalCenter]);
end;

不要忘记将列表框的Style属性设置为lbOwnerDrawFixed（比如说）。

更多＆＃34;高级＆＃34;方法是将实际对象与每个项目相关联：

type
  TItemFormat = class
    BackgroundColor: TColor;
    TextColor: TColor;
  end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i: Integer;
  ItemFormat: TItemFormat;
begin

  ListBox1.Items.BeginUpdate;
  try
    ListBox1.Clear;
    for i := 1 to 100 do
    begin
      ItemFormat := TItemFormat.Create;
      ItemFormat.BackgroundColor := IfThen(Odd(i), clSkyBlue, clMoneyGreen);
      ItemFormat.TextColor := IfThen(Odd(i), clNavy, clGreen);
      ListBox1.Items.AddObject(i.ToString, ItemFormat);
    end;
  finally
    ListBox1.Items.EndUpdate;
  end;

end;

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
var
  ListBox: TListBox;
  Canvas: TCanvas;
  ItemFormat: TItemFormat;
  S: string;
begin
  ListBox := Control as TListBox;
  Canvas := ListBox.Canvas;
  ItemFormat := ListBox.Items.Objects[Index] as TItemFormat;

  Canvas.Brush.Color := ItemFormat.BackgroundColor;
  Canvas.FillRect(Rect);
  S := ListBox.Items[Index];
  Canvas.Font.Color := ItemFormat.TextColor;
  Canvas.TextRect(Rect, S, [tfSingleLine, tfVerticalCenter]);
end;

（在这种情况下，您拥有对象，因此您有责任在不再需要它们时释放它们。）

将一切付诸行动

在您的特定情况下，我会尝试类似

的内容

procedure TForm1.Button1Click(Sender: TObject);
var
  i, dummy, FirstInvalidIndex: Integer;
begin

  with TOpenDialog.Create(Self) do
    try
      Filter := 'Text files (*.txt)|*.txt';
      Options := [ofPathMustExist, ofFileMustExist];
      if Execute then
        ListBox1.Items.LoadFromFile(FileName);
    finally
      Free;
    end;

  FirstInvalidIndex := -1;
  ListBox1.Items.BeginUpdate;
  try
    for i := 0 to ListBox1.Count - 1 do
      if not TryStrToInt(ListBox1.Items[i], dummy) then
      begin
        ListBox1.Items.Objects[i] := TObject(1);
        if FirstInvalidIndex = -1 then
          FirstInvalidIndex := i;
      end;
  finally
    ListBox1.Items.EndUpdate;
  end;

  if FirstInvalidIndex <> -1 then
  begin
    ListBox1.ItemIndex := FirstInvalidIndex;
    MessageBox(Handle, 'An invalid row was found.', PChar(Caption), MB_ICONERROR);
  end;

end;

procedure TForm1.ListBox1DrawItem(Control: TWinControl; Index: Integer;
  Rect: TRect; State: TOwnerDrawState);
var
  ListBox: TListBox;
  Canvas: TCanvas;
  S: string;
begin
  ListBox := Control as TListBox;
  Canvas := ListBox.Canvas;

  Canvas.Font.Assign(ListBox.Font);

  if odSelected in State then
  begin
    Canvas.Brush.Color := clHighlight;
    Canvas.Font.Color := clHighlightText;
  end
  else
  begin
    Canvas.Brush.Color := clWindow;
    Canvas.Font.Color := clWindowText;
  end;

  if ListBox.Items.Objects[Index] = TObject(1) then
  begin
    Canvas.Font.Color := clRed;
    Canvas.Font.Style := [fsBold, fsStrikeOut]
  end;

  Canvas.FillRect(Rect);
  S := ListBox.Items[Index];
  Canvas.TextRect(Rect, S, [tfSingleLine, tfVerticalCenter]);

end;

小字：请注意，上述代码段只是用于演示基本方法的简单示例。在实际应用程序中，您需要更加小心细节。例如，如果背景颜色是系统颜色，则不能使用硬编码的红色文本颜色（因为该颜色也可能是红色！）。

此外，如果文本文件为空，会发生什么（试试吧！）？

Answer 2

为列表框

设置lbOwnerDrawFixed（或其他所有者）

列表框项目具有辅助属性Objects[]，您可以将Objects[i]设置为无效项的非零值

IF NUM <> 0 then      
    LISTBOX1.Objects[N] := TObject(1);

使用一些示例进行OnDrawItem事件处理，并使用Objects[]在绘图期间定义背景颜色

Color Listbox.Item [N]其中N由代码生成

2 个答案:

简介

将一切付诸行动