我目前正在尝试为我的应用程序实现复制和粘贴，问题是我只能根据Gtk.Clipboard的文档将纯文本或图片写入剪贴板：https://valadoc.org/gtk+-3.0/Gtk.Clipboard.html set_text / set_image。
但是还有这个方法https://valadoc.org/gtk+-3.0/Gtk.Clipboard.set_with_data.html set_with_data，我认为我可以用来添加uri或uris数组。但我无法弄清楚如何找到任何好的例子。
更新
使用给定的答案我可以用uris数组填充剪贴板，但我可以阅读它们，当我尝试它时再次调用get_func并重新填充它。
CTRL C pressed
clipboard get_func called
Received: file:///home/marcel/Downloads/.gitignore
CTRL V pressd
clipboard get_func called
Received: file:///home/marcel/Downloads
Try Pasting: file:///home/marcel/Downloads
这是我用来测试CTRL + V的代码：
print ("\nCTRL V pressd\n");
clipboard.request_uris ((clipboard, uris) => {
foreach ( string content in uris ) {
print ("Try Pasting: ");
print (content);
print ("\n");
}
});
这是get_func的{{1}}的相关部分：
CTRL + C正如您在上面的终端输出中所看到的，它只是重新填充剪贴板，丢掉以前的值。
答案 0 :(得分：6)
根据要求，我提供了一个将URI写入剪贴板并从剪贴板获取URI的示例。这些示例基本上是命令行程序，可以立即获取/设置剪贴板。在实际的GUI应用程序中，您可能会对按下按钮做出反应，或者抓住 Ctrl C / Ctrl V 事件，使用Gtk.Widget.add_events()并在处理Gtk.Widget.event信号时获取/设置剪贴板。
您可以使用Gtk.Clipboard.request_uris ()从X11剪贴板请求URI。该函数接受一个URI可用后将被调用的回调。
示例：
public void main (string[] args) {
Gtk.init (ref args);
Gdk.Display display = Gdk.Display.get_default ();
Gtk.Clipboard clipboard = Gtk.Clipboard.get_for_display (display, Gdk.SELECTION_CLIPBOARD);
clipboard.request_uris (recieved_func);
Gtk.main ();
}
/* Gtk.ClipboardURIRecievedFunc */
private void recieved_func (Gtk.Clipboard clipboard, string[] uris) {
foreach (var uri in uris) {
print (uri + "\n");
}
Gtk.main_quit ();
}
使用valac clipget.vala --pkg=gtk+-3.0
由于没有标准方法可以复制和粘贴文件 目前，X11上的应用程序，各种MIME类型和约定 正在使用。例如，Nautilus期望文件提供一个 x-special / gnome-copied-files MIME类型，数据以。开头 剪切/复制操作，换行符和文件的URL。
Gtk.Clipboard未预先设置剪贴板以复制/剪切文件。如你所说，没有这样的Gtk.Clipboard.set_uris()。
相反，您应该通过提供X11从一次请求获取剪贴板内容的回调来设置剪贴板。
这些是必需的步骤：
创建一堆Gtk.TargetEntry，指定您的应用可以处理的剪贴板协议。您需要处理协议text/uri-list，x-special/gnome-copied-files和UTF8_STRING。每个TargetEntry都由其info字段标识，因此该数字应该是唯一的（请参阅下面示例中的enum ClipboardProtocol）
实施Gtk.ClipboardGetFunc类型的方法。此方法应填充与文件路径一起传递的Gtk.SelectionData对象以进行复制/剪切。检查info参数，以根据指定的协议设置SelectionData参数。
使用Gtk.Clipboard.set_with_owner或Gtk.Clipboard.set_with_data
enum ClipboardProtocol {
TEXT_URI_LIST,
GNOME_COPIED_FILES,
UTF8_STRING
}
public void main (string[] args) {
Gtk.init (ref args);
Gdk.Display display = Gdk.Display.get_default ();
Gtk.Clipboard clipboard = Gtk.Clipboard.get_for_display (display, Gdk.SELECTION_CLIPBOARD);
var clipboard_targets = new Gtk.TargetEntry[3];
Gtk.TargetEntry target_entry = { "text/uri-list", 0, ClipboardProtocol.TEXT_URI_LIST };
clipboard_targets[0] = target_entry;
target_entry = { "x-special/gnome-copied-files", 0, ClipboardProtocol.GNOME_COPIED_FILES };
clipboard_targets[1] = target_entry;
target_entry = { "UTF8_STRING", 0, ClipboardProtocol.UTF8_STRING };
clipboard_targets[2] = target_entry;
var owner = new Object ();
var rc = clipboard.set_with_owner (
clipboard_targets,
get_func,
clear_func,
owner
);
assert (rc);
clipboard.store ();
Gtk.main ();
}
/* Gtk.ClipboardGetFunc */
private void get_func (
Gtk.Clipboard clipboard,
Gtk.SelectionData selection_data,
uint info,
void* user_data_or_owner
) {
print ("GET FUNC!\n");
File my_file = File.new_for_path ("/home/lukas/tmp/test.txt");
File my_2nd_file = File.new_for_path ("/home/lukas/tmp/test2.txt");
File[] files = { my_file, my_2nd_file };
switch (info) {
case ClipboardProtocol.TEXT_URI_LIST:
string[] uris = {};
foreach (var file in files) {
uris += file.get_uri ();
}
selection_data.set_uris (uris);
break;
case ClipboardProtocol.GNOME_COPIED_FILES:
var prefix = "copy\n";
//var prefix = "cut\n";
/* use one of the above */
var builder = new StringBuilder (prefix);
for (int i = 0; i < files.length; i++) {
builder.append (files[i].get_uri ());
/* dont put the newline if this is the last file */
if (i != files.length - 1)
builder.append_c ('\n');
}
selection_data.set (
selection_data.get_target (),
8,
builder.data
);
break;
case ClipboardProtocol.UTF8_STRING:
var builder = new StringBuilder ();
foreach (var file in files) {
builder.append (file.get_parse_name ());
}
builder.append_c ('\n');
selection_data.set_text (builder.str, -1);
break;
default:
assert_not_reached ();
}
Gtk.main_quit ();
}
/* Gtk.ClipboardClearFunc */
private void clear_func (Gtk.Clipboard clipboard, void* data) {
;
}
使用valac clipset.vala --pkg=gtk+-3.0
几点说明：
在我的示例中，我只能测试x-special/gnome-copied-files，因为我此刻只安装了Nautilus。我修改了Thunar源代码中的所有协议（参见下面的来源），但它们可能仍需要排除故障*
如果您不想自己解决这个问题，也可以使用xclip命令行工具：https://askubuntu.com/a/210428/345569但是，恕我直言自己实现这一点会更优雅。