Question

如何使用xslt从xml节点获取子串的子串？

e.g。

输入：

<node>This Is W3 School</node>

输出：

<node>TIWS</node>

在这里，我想得到每个以空格分隔的子字符串的第一个字母。

Answer 1

<xsl:template match="node">
       <xsl:variable name="s" select="tokenize(.,' ')"/>

    <xsl:element name="node">
        <xsl:for-each select="$s">
        <xsl:value-of select="substring(.,1,1)"/>
        </xsl:for-each>
    </xsl:element>
   </xsl:template>
First of all tokenize the string then use substring for your desire output

Answer 2

谢谢你的所有答案。当我使用xslt versio：1.0时，我已经编写了子字符串函数来获得所需的输出。

  <?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:template match="node">
      <node1>
        <xsl:value-of select="substring(substring-before(normalize-space(substring-after(//node,'')),' '),1,1)"/>
        <xsl:value-of select="substring(substring-after(normalize-space(substring-after(//node,'')),' '),1,1)"/>
        <xsl:value-of select="substring(substring-before(normalize-space(substring-after(normalize-space(substring-after(//node,' ')),' ')),' '),1,1)"/>
        <xsl:value-of select="substring(substring-after(normalize-space(substring-after(normalize-space(substring-after(//node,' ')),' ')),' '),1,1)"/>
    </node1>
    </xsl:template>     
</xsl:stylesheet>

如果我可以减少相同xslt版本1.0中的代码，请告诉我

Answer 3

如果你坚持使用XSLT 1.0，你可以使用递归模板调用来处理字符串。

示例...

XML输入

<doc>
    <node>This Is W3 School</node>
    <node>One Two Three Four Five Six</node>
    <node>Hello </node>
    <node>      X   Y   Z      </node>
    <node/>    
</doc>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="node">
    <xsl:copy>
      <xsl:call-template name="first_letters"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template name="first_letters">
    <xsl:param name="input" select="normalize-space()"/>
    <xsl:variable name="remaining" select="substring-after($input,' ')"/>
    <xsl:value-of select="substring($input,1,1)"/>
    <xsl:if test="$input">
      <xsl:call-template name="first_letters">
        <xsl:with-param name="input" select="$remaining"/>
      </xsl:call-template>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

XML输出

<doc>
   <node>TIWS</node>
   <node>OTTFFS</node>
   <node>H</node>
   <node>XYZ</node>
   <node/>
</doc>

小提琴：http://xsltfiddle.liberty-development.net/6qVRKw1

如何使用xslt从xml节点获取子串的子串

3 个答案: