Question

我在dafny中有一张类似map<int,char>的地图，我想知道它是否包含某些值。

假设在dafny中还没有这方面的语法，我已经开始为它创建一个方法但是卡住了。到目前为止我的代码如下：

method containsValue(m: map<int,char>, val: char) returns (b: bool) 
    ensures b <==> exists i :: i in m && m[i] == val;
  {
    var i := 0;
    while (i < m.Length) {
        if (m[i] == val) 
          { return true; }      
      }
        return false;
    }

这不起作用，因为我不知道如何找到地图的大小，也可能存在其他一些问题。请帮忙

Answer 1

Modern Dafny使用地图的特殊.Values字段为其构建了语法，该字段返回地图中的一组值。地图还有一个.Keys用于返回键集。（不幸的是，.Keys和.Values目前都没有记录。我们正在努力。）

您可以在一行中表达您的方法，如下所示

method containsValue(m: map<int,char>, val: char) returns (b: bool) 
    ensures b <==> exists i :: i in m && m[i] == val;
{
    return val in m.Values;
}

Dafny自动验证是否满足其规范。

您还可以手动迭代地图元素，如下所示

method containsValue(m: map<int,char>, val: char) returns (b: bool)
    ensures b <==> exists i :: i in m && m[i] == val;
{
    var m' := m;
    while m'.Keys != {}
        invariant m'.Keys <= m.Keys
        invariant forall k | k in m' :: m'[k] == m[k]
        invariant (exists i :: i in m && m[i] == val) ==> (exists i :: i in m' && m'[i] == val)
        decreases m'.Keys
    {
        var k :| k in m';
        if m'[k] == val {
            return true;
        }
        m' := map k' | k' in m' && k' != k :: m'[k'];
    }
    return false;
}

Dafny的地图理解和内置语法通常会使这种迭代变得不必要，因此风格也很糟糕。（特别是对于这种方法，单行版本更清晰。）但是，它偶尔在其他情况下很有用，所以很了解这种技术。

Dafny检查地图包含价值

1 个答案: