Question

我已将Gradle构建脚本更改为使用Spring 2.0.1而不是1.5.9。当我运行gradle build时，我得到error: cannot find symbol Logger logger = Logger.getLogger(this.getClass().getName())。它与之前的Spring Boot版本配合得很好。代码使用import org.apache.log4j.Logger;。如何解决这个问题？

build.gradle档案：

buildscript {
    ext {
        springBootVersion = '2.0.1.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'jacoco'
apply plugin: 'war'

sourceCompatibility = 1.8

 repositories {
    mavenCentral()
        maven { url "https://repo.spring.io/snapshot" }
        maven { url "https://repo.spring.io/milestone" }
    }

bootRun {
    sourceResources sourceSets.main
}

sourceSets {
    main {
        java {
            srcDirs = ["src/main/java", "src/generated/main/java"]
        }
    }
}

dependencies {

    compile("org.springframework.boot:spring-boot-starter-web") {
        exclude module: "spring-boot-starter-tomcat"
    }

    providedRuntime group: 'org.springframework.boot', name: 'spring-boot-starter-tomcat'

    compile 'org.springframework.boot:spring-boot-starter-actuator'
    compile 'org.springframework.boot:spring-boot-starter'
    compile 'org.springframework.boot:spring-boot-starter-data-jpa'
    compile 'org.springframework.boot:spring-boot-starter-velocity:1.4.7.RELEASE'

    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310'
    compile 'com.ryantenney.metrics:metrics-spring:3.1.3'

    compile 'com.github.ben-manes.caffeine:caffeine:2.6.2'
    compile 'org.hibernate:hibernate-java8'
    compile 'org.postgresql:postgresql'
    compile 'org.apache.commons:commons-lang3:3.5'
    compile 'commons-codec:commons-codec:1.9'
    compile 'io.springfox:springfox-swagger2:2.6.1'
    compile 'io.springfox:springfox-swagger-ui:2.6.1'
    compile 'javax.mail:mail:1.4.7'
    compile 'org.imgscalr:imgscalr-lib:4.2'
    compile 'com.restfb:restfb:1.37.0'
    compile 'com.google.apis:google-api-services-oauth2:v2-rev134-1.23.0'
    compile 'eu.bitwalker:UserAgentUtils:1.19'
    compile 'com.twilio.sdk:twilio:7.17.+'

    testCompile('com.h2database:h2')
    testCompile("org.springframework.boot:spring-boot-starter-test")

    compile fileTree(dir: 'libs', include: '*.jar')
}

Answer 1

默认情况下，Spring引导提供Logback和SLF4J来执行日志记录，如the documentation中所述。但是，您可以通过包含以下依赖项来交换log4j的logback：

log4j 1.x spring-boot-starter-log4j
log4j 2.x spring-boot-starter-log4j2

但是，对log4j 1.x的支持已被删除since Spring boot 1.4.x，因为Apache不再支持它：

在Apache EOL announcement之后删除了Log4j 1支持。

您仍然可以手动添加所有依赖项，但由于您没有这些依赖项，这可能是它不再有效的原因（可能其中一个库之前使用过log4j）。您必须添加以下依赖项：

compile 'org.slf4j:slf4j-log4j12:1.7.25'
compile 'org.slf4j:jul-to-slf4j:1.7.25'
compile 'org.slf4j:jcl-over-slf4j:1.7.25'
compile 'log4j:log4j:1.2.17'

您还必须排除spring-boot-starter-logging，如this answer中所述，您可以通过添加以下配置来执行此操作：

configurations {
    compile.exclude module: 'spring-boot-starter-logging'
}

但是，建议将SLF4J与Logback一起使用，或者将SLF4J与log4j2一起使用。

Answer 2

Spring Boot 2默认使用Logback和SLF4J 你可以选择使用一个桥接器，它将log4j 1连接到slf4j，如下所示：

compile group: 'org.slf4j', name: 'log4j-over-slf4j', version: '1.7.25'

但是我建议你切换你的代码使用slf4j（如果你的代码库很大，这可能需要一些时间）。

错误：在Spring 1.5.9升级到2.0.1之后找不到符号Logger logger = Logger.getLogger（this.getClass（）。getName（））

2 个答案: