Question

我的目标是获取输出XML文件的姓氏和客户端的数量。我希望匹配来自<ClientList>的ID和来自<AmountList>的ID，如果有相同的显示金额。我的XSL文件无法正常工作。

我有这样一个XML文件：

<?xml version="1.0" encoding="utf-8"?>
<myData>
<ClientList>
    <Client>
        <surname>Kowalski</surname>
        <id>12</id>
    </Client>
    <Client>
        <surname>Nowak</surname>
        <id>13</id>
    </Client>
</ClientList>
<AmountList>
     <Client>
        <id>12<id>
        <amount>500</amount>
    </Client>
    <Client>
       <id>13<id>
       <amount>300</amount>
</Client>
</AmountList>
<myData>

我想获得这个XML：

<ClientList>
<Client>
   <surname>Kowalski</surname>
   <amount>500</amount>
</Client>
<Client>
  <surname>Nowak</surname>
  <amount>300</amount>
</Client>
</ClientList>

我的XSL文件无法正常运行：

<xsl:template match="/">
<ClientList>
<xsl:for-each select="ClientList/Client">
<Client>
   <surname>
       <xsl:value-of select="surname" />
   </surname>
   <amount>
       <xsl:variable name="Var1" select="substring(id, 1, 2)" />
       <xsl:variable name="Var2" select="substring(id, 1, 2)" />
       <xsl:if test="Var1 = Var2">AmountList/Client/amount</xsl:if> 
   </amount>
</Client>
</xsl:for-each>
</ClientList>

Answer 1

首先，您的输入XML存在一些小问题：<id>中的<AmountList>个节点未正确关闭，并且您错过了结束标记对于根节点<myData>。

修好了，这是我的建议：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="/myData">
    <ClientList>
        <xsl:for-each select="ClientList/Client">
        <Client>
            <surname>
                <xsl:value-of select="surname" />
            </surname>
            <amount>
                <xsl:value-of select="/myData/AmountList/Client[id=current()/id]/amount" />
            </amount>
        </Client>
        </xsl:for-each>
    </ClientList>
    </xsl:template>
</xsl:stylesheet>

xPath表达式/myData/AmountList/Client[id=current()/id]/amount表示：

从根目录开始，找到/myData/AmoutList/Client节点，其 id子节点等于 id子节点当前上下文节点，然后选择此节点的amount子节点。

current()函数是能够执行此类查找的关键，您可以根据相对于当前节点的值，在某个节点的输入树中查找其他位置上。

在这种情况下，current()返回的当前上下文节点是Client节点，因为它是for-each选择的内容。我发现最好始终了解当前上下文节点在XSL转换中的任何位置。

Answer 2

 <xsl:template match="myData">
        <xsl:for-each select="ClientList/Client">
            <xsl:if test="id=../following-sibling::AmountList/Client/id">
                <xsl:element name="ClientList">
                    <xsl:element name="Client">
                <xsl:element name="surname">
                    <xsl:value-of select="surname"/>
                </xsl:element>
                        <amount>
                            <xsl:value-of select="../following-sibling::AmountList/Client[id=current()/id]/amount"/>
                        </amount>
                    </xsl:element>
                </xsl:element>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

如何比较XML文件中的id

2 个答案: