Question

我有一个脚本返回以下结果：

现在我需要找到最高的整数（在这种情况下＆amp; p = 29）并创建从https://XY.com/search?q=mad%20dog&p=0到最高找到的整数的新字符串https://XY.com/search?q=mad%20dog&p=29

到目前为止，我设法使用以下代码提取所需的网址：

set AllUrls to {"https://XY.com/search?q=mad%20dog&p=26", "https://XY.com/search?q=mad%20dog&p=29", "https://XY.com/shop/General-Mad-Dog-Mattis-For-PrN"}

-- FILTER PAGING URLS
set PagingFilter to "&p="
set PagingUrls to {}
repeat with i from 1 to length of AllUrls
    if item i of AllUrls contains PagingFilter then

        set end of PagingUrls to item i of AllUrls
    end if
end repeat
PagingUrls -- returns {"https://XY.com/search?q=mad%20dog&p=26", "https://XY.com/search?q=mad%20dog&p=29"}

从网址中提取最后2位的小脚本：

set alphabet to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
set myURLs to {"https://XY.com/search?q=mad%20dog&p=26", "https://XY.com/search?q=mad%20dog&p=29"}
set the text item delimiters of AppleScript to ¬
    {space} & characters of the alphabet & {".", "_"}
set a to text items of myURLs as text

get last word of a --> returns "21"


set numlist to {}
repeat with i from 1 to count of words in a

    set this_item to word i of a
    try
        set this_item to this_item as number
        set the end of numlist to this_item

    end try

end repeat
numlist -- returns {26, 29}

Answer 1

这是另一种方法。

它通过分隔符text item delimiters将&p=的网址拆分。如果分隔符存在，则获取整数（分隔符的右侧），如果当前值高于先前值，则将其保存为maxValue。

然后使用循环创建页面URL列表

set AllUrls to {"https://XY.com/search?q=mad%20dog&p=26", "https://XY.com/search?q=mad%20dog&p=29", "https://XY.com/shop/General-Mad-Dog-Mattis-For-PrN"}

set maxValue to 0
set baseURL to ""
set TID to text item delimiters
set text item delimiters to "&p="
repeat with anURL in AllUrls
    set textItems to text items of anURL
    if (count textItems) is 2 then
        set currentValue to item 2 of textItems as integer
        if currentValue > maxValue then set maxValue to currentValue
        set baseURL to item 1 of textItems & "&p="
    end if
end repeat
set text item delimiters to TID
set pageURLs to {}
repeat with i from 0 to maxValue
    set end of pageURLs to baseURL & i
end repeat

Applescript |提取最高整数并创建从0到最高整数的数字

1 个答案: