Question

以下代码给出了奇怪的结果。切片机有22个选项（顶部＃1下至底部＃22）。

如果我当前选择＃12，然后运行代码，它将选择切片器选项1-12。如果X =当前所选切片器选项的＃，则代码将选择1 - X，并且下面的选项保持未选中状态。以上仅是一个示例，并不意味着显示自然或期望的起点。

可能相关的其他信息： Multiselect = True，第二个到底部选项=＆＃34;＆＃34;，最后一个选项 - ＆＃34;空白＆＃34;

我想要代码做的是选择倒数第三个选项，这是第一个（从下面）选项，它不是空白或空数据。这解释了注释掉的行。

但是，我无法弄清楚为什么下面的代码没有取消选择所有选项。

Sub Slicer()

Dim WB As Workbook
Set WB = ThisWorkbook
Dim i As Integer
Dim n As Integer



With WB.SlicerCaches("Slicer_Processed_date")
    n = .SlicerItems.Count

    For i = 1 To n
        If .SlicerItems(i).Selected = True Then
            .SlicerItems(i).Selected = False
        End If
    Next i

   '.SlicerItems(n - 2).Selected = True
End With   
End Sub

Answer 1

您无法取消选择所有项目。您必须始终保持一个项目可见，否则VBA将抛出错误。

如果您想要现成的代码来过滤阵列上的切片器，请在How to update slicer cache with VBA

查看我的答案

如果你愿意，那个数组可以只有一个东西。该代码中的注释将帮助您了解如何有效地过滤切片器。

编辑：现在我明白了你的需要，请使用：

Sub SliceByIndex()


Dim sc As SlicerCache
Dim si As SlicerItem
Dim l As Long
Dim i As Long

Set sc = ThisWorkbook.SlicerCaches("Slicer_Test")

l = sc.SlicerItems.Count
With sc
    .PivotTables(1).ManualUpdate = True 'Stops PivotCache recalculating until we are done

    ' Select the first item, because one item MUST remain visible at all times.
    ' We'll unselected it when we're done
    .SlicerItems(1).Selected = True

    'Deselect everything else
    For i = 2 To l
        .SlicerItems(i).Selected = False
    Next i

    'Select the desired item
    .SlicerItems(l - 2).Selected = True

    'Deselect the first items
    .SlicerItems(1).Selected = False

    'Turn the PivotCache calculation on again
    .PivotTables(1).ManualUpdate = False
End With


End Sub

VBA取消选择所有切片器选项（1除外）

1 个答案: