Question

我是XQuery的新手（来自SQL），我正在尝试编写一个查询，选择另一个表中不存在的所有结果。

更具体地说，我使用的是这个XML数据库： https://www.dbis.informatik.uni-goettingen.de/Mondial/mondial.xml 我试图选择所有没有任何岛屿的国家

XML查询：

let $islands := doc("mondial.xml")/mondial/island/located/data(@country)

for $country in doc("mondial.xml")/mondial/country
let $c_code := $country/data(@car_code)
let $c_name := data($country/name)
where not($c_code=$islands)
order by $c_name
return $c_name

相同的查询，但在SQL中：

SELECT name 
FROM Country 
WHERE code 
NOT IN (SELECT country FROM geo_island);

（等效SQL数据库的关系模式：https://www.dbis.informatik.uni-goettingen.de/Mondial/mondial-RS.pdf）

我在结果中应该获得的正确数量是120，但我得到210个国家/地区。我做错了什么？

编辑：如果我之前没有说清楚：我在编写XQuery查询之前编写了SQL查询。我只是想将SQL查询转换为XQuery查询。

Answer 1

岛屿所属的国家/地区位于/mondial/island/@country，而不是/mondial/island/located/@country。例如，参见 Ireland 的条目：

<island id="island-Ireland" country="IRL GB" sea="sea-Irische_See sea-Atlantic">
  <name>Ireland</name>
  <islands>British Isles</islands>
  <located country="GB" province="prov-gb-12"/>
  <area>84421</area>
  <latitude>53.5</latitude>
  <longitude>-7.8</longitude>
  <elevation>1041</elevation>
</island>

爱尔兰国家和英国（即北爱尔兰）都在爱尔兰岛上，因此在/mondial/island[name = 'Ireland']/@country中有两个以空格分隔的条目。

您可以使用fn:tokenize($string[, $separator])获取所有单个国家/地区（以提高效果）获取所有拥有fn:distinct-values($sequence)的独立岛屿国家/地区。其余的可以保持不变：

let $doc := doc("mondial.xml")
let $islands := distinct-values($doc/mondial/island/@country/tokenize(.))
for $country in $doc/mondial/country
let $c_code := $country/data(@car_code)
let $c_name := data($country/name)
where not($c_code=$islands)
order by $c_name
return $c_name

现在按预期返回120个国家。

XQuery - “NOT IN”等效不能按预期工作

1 个答案: