Question

当我使用XML序列化程序序列化DateTime时，它采用以下格式编写：

<Date>2007-11-14T12:01:00</Date>

当通过XSLT样式表传递它以输出HTML时，我该如何格式化？在大多数情况下，我只需要约会，当我需要时间时，我当然不希望那里有“有趣的T”。

Answer 1

以下是一些可以使用的1.0模板： -

<xsl:template name="formatDate">
    <xsl:param name="dateTime" />
    <xsl:variable name="date" select="substring-before($dateTime, 'T')" />
    <xsl:variable name="year" select="substring-before($date, '-')" />
    <xsl:variable name="month" select="substring-before(substring-after($date, '-'), '-')" />
    <xsl:variable name="day" select="substring-after(substring-after($date, '-'), '-')" />
    <xsl:value-of select="concat($day, ' ', $month, ' ', $year)" />
</xsl:template>

<xsl:template name="formatTime">
    <xsl:param name="dateTime" />
    <xsl:value-of select="substring-after($dateTime, 'T')" />
</xsl:template>

用以下方式打电话给他们： -

    <xsl:call-template name="formatDate">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

和

    <xsl:call-template name="formatTime">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

其中xpath是具有标准日期时间格式的元素或属性的路径。

Answer 2

XSLT 1.0中的日期格式化并不容易。可能最优雅的方法是在C＃中编写一个简短的XSLT扩展函数来进行日期格式化。这是一个例子：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                xmlns:myExtension="urn:myExtension"
                exclude-result-prefixes="msxsl myExtension">
  <xsl:output method="xml" indent="yes"/>

  <msxsl:script implements-prefix="myExtension" language="C#">
    <![CDATA[
      public string FormatDateTime(string xsdDateTime, string format)
      {
          DateTime date = DateTime.Parse(xsdDateTime);
          return date.ToString(format); 
      }

    ]]>
  </msxsl:script>

  <xsl:template match="date">
    <formattedDate>
      <xsl:value-of select="myExtension:FormatDateTime(self::node(), 'd')"/>
    </formattedDate>
  </xsl:template>
</xsl:stylesheet>

使用此输入文档

<?xml version="1.0" encoding="utf-8"?>
<date>2007-11-14T12:01:00</date>

你会得到

<?xml version="1.0" encoding="utf-8"?>
<formattedDate>14.11.2007</formattedDate>

格式化日期的函数将日期值作为字符串，格式如DateTime.ToString Method中所述。使用.NET的DateTime结构，您可以免费解析任意XSD日期时间值（包括时区说明符），时区计算和本地化输出。

但是，请注意，有一个带有msxml脚本扩展的caveat (http://support.microsoft.com/kb/316775)：每次加载XSLT时，都会动态生成包含脚本代码的程序集并将其加载到内存中。由于.NET运行时的设计，无法卸载此程序集。这就是为什么你必须确保你的XSLT只加载一次（然后缓存以供进一步重用）。在IIS中运行时，这一点尤其重要。

Answer 3

John Workman详细讨论了这个问题，并在他的博客中提供了discussion ^[1]中的几个解决方案。基本上，解析各个日期组件并按您希望的顺序重新组合。对于您的情况，纯XSLT 1.0+版本将是：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="date">
<!-- converts FROM <date>2001-12-31T12:00:00</date> TO some new format (DEFINED below) -->
<xsl:template name="FormatDate">
<xsl:param name="DateTime" />

<xsl:variable name="year" select="substring($DateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($DateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($DateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<!-- EUROPEAN FORMAT -->
<xsl:value-of select="$day"/>
<xsl:value-of select="'.'"/> <!--18.-->
<xsl:value-of select="$month"/>
<xsl:value-of select="'.'"/> <!--18.03.-->
<xsl:value-of select="$year"/>
<xsl:value-of select="' '"/> <!--18.03.1976 -->
<xsl:value-of select="$hh"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13: -->
<xsl:value-of select="$mm"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13:24 -->
<xsl:value-of select="$ss"/> <!--18.03.1976 13:24:55 -->
<!-- END: EUROPEAN FORMAT -->

</xsl:template>

另一种格式（REPLACEs EUROPEAN FORMAT部分）：

<!-- Long DATE FORMAT -->
<xsl:choose>
<xsl:when test="$month = '1' or $month= '01'">January</xsl:when>
<xsl:when test="$month = '2' or $month= '02'">February</xsl:when>
<xsl:when test="$month= '3' or $month= '03'">March</xsl:when>
<xsl:when test="$month= '4' or $month= '04'">April</xsl:when>
<xsl:when test="$month= '5' or $month= '05'">May</xsl:when>
<xsl:when test="$month= '6' or $month= '06'">June</xsl:when>
<xsl:when test="$month= '7' or $month= '07'">July</xsl:when>
<xsl:when test="$month= '8' or $month= '08'">August</xsl:when>
<xsl:when test="$month= '9' or $month= '09'">September</xsl:when>
<xsl:when test="$month= '10'">October</xsl:when>
<xsl:when test="$month= '11'">November</xsl:when>
<xsl:when test="$month= '12'">December</xsl:when>
</xsl:choose> 
<xsl:value-of select="' '"/> <!--January -->
<xsl:value-of select="$day"/> <!--January 12 -->
<xsl:value-of select="','"/> <!--January 12,-->
<xsl:value-of select="' '"/> <!--January 12, -->
<xsl:value-of select="$year"/> <!--January 12, 2001-->
<!-- END: Long DATE FORMAT -->

您可以以您选择的任何方式重新组合元素。

[1] http://geekswithblogs.net/workdog/archive/2007/02/08/105858.aspx @@ http://archive.is/4Hjep

Answer 4

对这个旧帖子发表评论表示歉意，但对于其他发现它的人来说，如果你使用的是MS变压器，你也可以使用javascript：

声明“msxsl”命名空间：

xmlns:msxsl="urn:schemas-microsoft-com:xslt"

为脚本声明命名空间：

xmlns:js="urn:custom-javascript"

（可选）省略输出中的前缀：

exclude-result-prefixes="msxsl js"

所以你最终会得到像这样的xsl声明：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  xmlns:js="urn:custom-javascript"
  exclude-result-prefixes="msxsl js">

在msxsl：script元素中编写JavaScript：

<msxsl:script language="JavaScript" implements-prefix="js"> 
<![CDATA[ 
function javascriptFunction(dateValue){
  var date = new Date(dateValue);
  if(!isNaN(date)) return date.toLocaleString();
  return dateValue;
}
]]>
</msxsl:script>

调用您的JavaScript函数（使用XPath语法'。'表示'此节点'）：

<xsl:value-of select="js:javascriptFunction(string(.))"/>

注意：在编写时，似乎没有（xsl）方式包含外部js文件（例如jquery库）。这可以通过在转换之前解析xsl文件服务器端并将js文件内容作为字符串添加到CDATA部分来完成。我自己开始沿着这条路走下去，但得出的结论是，如果你需要这种功能，可能最好放在管道的不同部分。

来源：http://dev.ektron.com/kb_article.aspx?id=482
参考：http://www.ibm.com/developerworks/xml/library/x-tipxsltjs/index.html

Answer 5

对roy的帖子进行更正：从函数开始的那一天将始终获得月份值。使用以下内容：

<xsl:variable name="year" select="substring($dateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($dateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($dateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<xsl:value-of select="concat($month,'/',$day,'/',$year,' ',$hh,':',$mm,':',$ss)" />

Answer 6

谢谢，这篇文章帮了很多忙。

我正在转换使用以下日期格式的RSS Feed：周一，2011年4月4日23:18:00 -0700 。这是我用来解析它的命名模板。

<!--Parse date format: Mon, 04 Apr 2011 23:18:00 -0700-->
<xsl:template name="formatDate">

    <xsl:param name="dateIn" />

    <xsl:variable name="day" select="substring($dateIn, 0, 3)" />
    <xsl:variable name="date" select="substring($dateIn, 6, 2)" />
    <xsl:variable name="month" select="substring($dateIn, 9, 3)" />
    <xsl:variable name="year" select="substring($dateIn, 13, 4)" />

    <xsl:variable name="hour" select="substring($dateIn, 18, 2)" />
    <xsl:variable name="min" select="substring($dateIn, 21, 2)" />
    <xsl:variable name="sec" select="substring($dateIn, 24, 2)" />

    <xsl:value-of select="concat($date, ' ', $month, ' ', $year, ' ', $hour, ':', $min, ':', $sec)" />

</xsl:template>

Answer 7

<xsl:template match="date">
     <xsl:copy>
         <xsl:call-template name="formatdate">
             <xsl:with-param name="DateTimeStr" select="."/>
        </xsl:call-template>
     </xsl:copy>
  </xsl:template>

  <xsl:template name="formatdate">
     <xsl:param name="DateTimeStr" />

     <!-- input format xslt datetime string -->
     <!-- output format mm/dd/yyyy -->

     <xsl:variable name="datestr">
         <xsl:value-of select="substring-before($DateTimeStr,'T')" />
     </xsl:variable>

     <xsl:variable name="mm">
         <xsl:value-of select="substring($datestr,6,2)" />
     </xsl:variable>

     <xsl:variable name="dd">
        <xsl:value-of select="substring($datestr,9,2)" />
     </xsl:variable>

     <xsl:variable name="yyyy">
        <xsl:value-of select="substring($datestr,1,4)" />
     </xsl:variable>

     <xsl:value-of select="concat($mm,'/', $dd, '/', $yyyy)" />
  </xsl:template>

这对我有用。您可以在以下位置查看其他选项：

https://blog.fpmurphy.com/2008/05/xslt-datetime-formatting.html

通过XSLT格式化XML格式的日期

7 个答案: