Question

我想创建一个类型泛型STRUCT和一个配对Function Block，它接受并返回泛型类型的变量（假设为ANY_NUM）。

需要使用通用数字类型probably belonging to the ANY_NUM type将相同格式的许多现有STRUCT和FB对压缩为一个通用对。

在C ++中，通用结构将使用Template Class完成，但我在结构化文本中找不到类似的结构。

我尝试了通用功能块on Beckhoff's ANY/ANY_(TYPE) page，但很快就失败了convert type 'LREAL' to type '__SYSTEM.AnyType'。

问题：

我可以在多大程度上在结构化文本中实现这一目标？

修改

我错误地认为ANY是唯一相关的ST通用。我被指示type T_Arg作为潜在可行的候选人。

尝试的示例格式：

结构：

TYPE Bounded_Value:
STRUCT
    Value   : ANY_NUM;
    Min_    : ANY_NUM;
    Max_    : ANY_NUM;
END_STRUCT
END_TYPE

功能块：

FUNCTION_BLOCK Bind_Value
VAR_IN_OUT
    value_struct: Bounded_Value;
END_VAR

（实施会将value_struct.Value绑定到value_struct.min_和value_struct.max_之间

Answer 1

我最近在TwinCAT中对此进行了调查（任何类型）。您基本上需要做的是将ANY指针指向的每个字节转换为LREAL（根据IEC61131-3，您知道的字节总是8字节）。 ANY类型保存有关它指向的类型的信息，因此通过解析ANY指针指向的数据结构，您将知道它何时是LREAL。请在我的博客上阅读我的完整调查：The wonders of ANY

Answer 2

（我从Stefan Henneken's blog post on T_Arg收集了我的问题的解决方案。）

目标可以实现，但不是特别干净。到目前为止，我有两种适用的通用类型：ANY_NUM和T_Arg。

（我使用ANY_NUM因为它与此示例最相关。ANY，ANY_REAL或ANY_INT也是合理的选项）

两种选择都具有相似的结构和功能。每个结构都包含有关存储变量的信息：其类型，指向它的指针及其大小。

然而每个人都有利弊。为了最准确地解决这个问题，我们将使用 T_Arg 。

区别在于：

ANY / ANY_NUM / ETC

优势：分配变量时，ANY_NUM的变量转换为implicitly。输入变量在输入函数之前不需要预转换，减少了代码的大小。

此外，它只接受属于其域的变量，因此不会意外使用字符串。

缺点： ANY_NUM无法在VAR_INPUT块之外声明，实际上，在尝试时会提供此错误消息：

Variables of type 'ANY_NUM' only allowed as input of functions.

因此，ANY_NUM不能用作STRUCT变量，即使STRUCT被声明为函数的输入。这就是它无法用于解决这一特定问题的原因。

T_Arg

优势： T_Arg可以在任何地方声明和使用。

缺点： T_Arg需要任何预期变量类型的转换函数，例如： F_INT()，F_REAL()，F_DINT()等

因此，需要在输入之前和之后执行类型检查。

示例解决方案

不幸的是，T_Arg中存储的变量无法直接操作。有必要将存储的变量移动到临时变量以使用它。因此，Value，Min_和Max_都需要从T_Arg类型转换为REAL / INT /等类型。

由于我们只尝试使用一个STRUCT，Value需要在Bind_Value完成操作后再次转换为T_Arg。

总的来说，Value在实例化时会被转换三次，之后会被转换两次。

<强>结构：

TYPE Bounded_Value:
STRUCT
    Value   : T_Arg;
    Min_    : T_Arg;
    Max_    : T_Arg;
END_STRUCT
END_TYPE

功能块：

FUNCTION_BLOCK Bind_Value
VAR_IN_OUT
    value_struct: Bounded_Value;
    // Other variable type declarations
END_VAR
VAR
    val_int     :   INT;
    max_int     :   INT;
    min_int     :   INT;
END_VAR

CASE (value_struct.Value.eType) OF
    E_ArgType.ARGTYPE_INT: // If the struct's Value's type is INT
        // Copy generic pointer information into typed pointer 
        MEMCPY(ADR(val_int), value_struct.Value.pData, value_struct.Value.cbLen);
        MEMCPY(ADR(max_int), value_struct.Max_.pData,  value_struct.Max_.cbLen);
        MEMCPY(ADR(min_int), value_struct.Min_.pData,  value_struct.Min_.cbLen);

        IF val_int > max_int THEN
            value_struct.Value.pData := value_struct.Max_.pData;
        ELSIF val_int < min_int THEN
            value_struct.Value.pData := value_struct.Min_.pData;
        END_IF
    // Other variable type handlings
END_CASE

主要：

PROGRAM MAIN
VAR
    val     : INT := -1; //Change this to test
    minim   : INT :=  0;
    maxim   : INT :=  5;
    newVal  : INT;
    bv      : Bounded_Value;
    bind    : Bind_Value;
END_VAR

// Convert INT variables to T_Arg in structure
bv.Value:= F_INT(val);
bv.Max_ := F_INT(maxim);
bv.Min_ := F_INT(minim);
// Bind_Value.value_struct := bv;
bind(value_struct := bv);
// Copy result to newVal
MEMCPY(ADR(newVal), bv.Value.pData, bv.Value.cbLen);

Answer 3

您还可以借助功能块和联合创建通用类型。假设您定义了一个包含所有DUT和POU的联合：

TYPE GenericType :
UNION
    generic : PVOID;
    bBool   : REFERENCE TO BOOL;
    nInt    : REFERENCE TO INT;
    nUint   : REFERENCE TO UINT;
    nUdint  : REFERENCE TO UDINT;
    fReal   : REFERENCE TO REAL;
    fLreal  : REFERENCE TO LREAL;
    fbTest  : REFERENCE TO FB_Test;
END_UNION
END_TYPE

然后创建一个特殊的功能块：

FUNCTION_BLOCK Generic
VAR_INPUT
END_VAR
VAR_OUTPUT
END_VAR
VAR
    uGenericType : GenericType;
END_VAR

还有一个获取并设置PVOID的属性：

PROPERTY PUBLIC generic : PVOID

吸气剂：

generic := uGenericType.generic;

二传手：

uGenericType.generic := generic;

您还需要“属性”以便以后检索您的类型：

Image of the FB

getBool设置程序的示例可能是：

IF uGenericType.generic = 0 
THEN
    RETURN;
ELSE
    getBool := uGenericType.bBool;
END_IF

现在，您将创建将使用通用类型的FB：

FUNCTION_BLOCK FB_Container
VAR_INPUT

    myGenericType       : Generic;
    nContainerOption    : INT;

END_VAR
VAR_OUTPUT
END_VAR
VAR

    testInt             : INT;
    testBool            : BOOL;
    testFB              : FB_Test;

END_VAR

CASE nContainerOption OF

    1:
        testInt := myGenericType.getInt;

    2:
        testFB := myGenericType.getFbTest;

    3:
        testBool := myGenericType.getBool;

END_CASE

通话可能是这样的：

fbContainer.myGenericType.generic := ADR(testInteger);
...
fbContainer(nContainerOption := 1);

另一种方法是使用通用FB扩展我们的FB。但是，我们需要对Generic FB和GenericType Union进行一些修改：

FUNCTION_BLOCK Generic
VAR_INPUT
END_VAR
VAR_OUTPUT
END_VAR
VAR
    uGenericType    : GenericType;
    bInit           : BOOL;
END_VAR

IF NOT bInit THEN
 uGenericType.generic := ADR(THIS^);
 bInit := TRUE;
END_IF

TYPE GenericType :
UNION
    generic : PVOID;

    //Add the pointer of the FB you want to extend
    pAxis   : POINTER TO FB_Axis;

    bBool   : REFERENCE TO BOOL;
    nInt    : REFERENCE TO INT;
    nUint   : REFERENCE TO UINT;
    nUdint  : REFERENCE TO UDINT;
    fReal   : REFERENCE TO REAL;
    fLreal  : REFERENCE TO LREAL;
    fbTest  : REFERENCE TO FB_Test;

END_UNION
END_TYPE

扩展的FB：

FUNCTION_BLOCK FB_Axis EXTENDS Generic
VAR_INPUT
END_VAR
VAR_OUTPUT
END_VAR
VAR
    fPosition : LREAL;
END_VAR

现在像以前一样调用我们的容器：

fbContainer.myGenericType := fbAxis;

在FB_Container中，您可以按以下方式调用轴：

IF myGenericType.getPointerFbAxis <> 0 
THEN
    position := myGenericType.getPointerFbAxis^.fPosition;
END_IF

在Struct＆amp;中使用泛型类型功能块

3 个答案:

ANY / ANY_NUM / ETC

T_Arg

示例解决方案