Question

Oracle定义了几种结构，这些结构利用了懒惰的评估，但实际上是短路的。

例如：

x := case when 1 = 2 then count_all_prime_numbers_below(100000000)
          else 2*2
     end;

永远不会调用函数count_all（...）。

然而，我更感兴趣的是看起来像常规函数调用的语法：

x := coalesce(null, 42, hundreth_digit_of_pi());

Hundreth_digit_of_pi（）不会被调用，因为coalesce不是常规函数，而是一个看起来像一个的语法糖 - 在调用函数时会对常规函数进行求值。

问题是：是否可以在plsql中定义一个行为方式相同的自定义过程/函数？

如果你不相信我会举一个有用的例子：

我们使用''framework''进行日志记录。要追踪你称之为程序的东西：

trace_something('A text to be saved somewhere');

Trace_something是'pragma自治事务'过程，执行以下步骤： 1.如果启用了任何跟踪方法（例如文件/ db表），请参阅 2.对于每个启用的方法，使用该方法在某处保存参数。 3.如果它已保存到DB，则提交。

当构建要跟踪的实际字符串可能需要花费大量时间时会出现问题，如果首先甚至没有启用跟踪，我们也不希望花费它。

目标是伪代码：

procedure lazily_trace_something(some_text lazily_eval_type) {
    if do_i_have_to_trace() = TRUE then
        trace_something(evaluate(some_text));
    else
        NULL; -- in which case, some_text doesn't get evaluated     
    end if;
}


/*

*/

lazily_trace_something(first_50_paragraphs_of_lorem_ipsum(a_rowtype_variable));

是否可以在plsql中完成？

Answer 1

可以使用ref游标，条件编译或执行立即（部分）实现延迟评估。 ANYDATA类型可用于传递通用数据。

参考光标

可以使用静态SQL语句打开Ref游标，作为参数传递，并且在需要之前不会执行。

虽然这确实回答了关于懒惰评估的问题，但我不确定它是否真的很实用。这不是ref游标的预期用途。并且必须向所有内容添加SQL可能不方便。

首先，要证明慢速函数正在运行，请创建一个只能休眠几秒钟的函数：

grant execute on sys.dbms_lock to <your_user>;

create or replace function sleep(seconds number) return number is
begin
    dbms_lock.sleep(seconds);
    return 1;
end;
/

创建一个函数来确定是否需要进行评估：

create or replace function do_i_have_to_trace return boolean is
begin
    return true;
end;
/

此函数可以通过执行SQL语句来执行工作。 SQL语句必须返回一些内容，即使您可能不需要返回值。

create or replace procedure trace_something(p_cursor sys_refcursor) is
    v_dummy varchar2(1);
begin
    if do_i_have_to_trace then
        fetch p_cursor into v_dummy;
    end if;
end;
/

现在创建始终会调用trace的过程，但不一定会花时间评估参数。

create or replace procedure lazily_trace_something(some_number in number) is
    v_cursor sys_refcursor;
begin
    open v_cursor for select sleep(some_number) from dual;
    trace_something(v_cursor);
end;
/

默认情况下，它正在开展工作并且速度很慢：

--Takes 2 seconds to run:
begin
    lazily_trace_something(2);
end;
/

但是当你改变DO_I_HAVE_TO_TRACE以返回false时，程序很快，即使它传递了一个缓慢的参数。

create or replace function do_i_have_to_trace return boolean is
begin
    return false;
end;
/

--Runs in 0 seconds.
begin
    lazily_trace_something(2);
end;
/

其他选项

传统上，条件编译用于启用或禁用检测。例如：

create or replace package constants is
    c_is_trace_enabled constant boolean := false;
end;
/

declare
    v_dummy number;
begin
    $if constants.c_is_trace_enabled $then
        v_dummy := sleep(1);
        This line of code does not even need to be valid!
        (Until you change the constant anyway)
    $else
        null;
    $end
end;
/

您可能还想重新考虑动态SQL。编程风格和一些语法糖可以在这里产生很大的不同。简而言之，替代引用语法和简单模板可以使动态SQL更具可读性。有关详细信息，请参阅我的帖子here。

传递通用数据

ANY类型可用于存储和传递任何可以想象的数据类型。不幸的是，每种行类型都没有本机数据类型。您需要为每个表创建一个TYPE。这些自定义类型非常简单，因此必要时可以自动执行步骤。

create table some_table(a number, b number);
create or replace type some_table_type is object(a number, b number);

declare
    a_rowtype_variable some_table_type;
    v_anydata anydata;
    v_cursor sys_refcursor;
begin
    a_rowtype_variable := some_table_type(1,2);
    v_anydata := anydata.ConvertObject(a_rowtype_variable);
    open v_cursor for select v_anydata from dual;
    trace_something(v_cursor);
end;
/

自定义延迟评估/短路函数参数的语法

1 个答案:

参考光标

其他选项

传递通用数据