Question

这是我第一次提出问题，所以如果我做错了，请冷静。

您好，

我的Visual Studio解决方案由CMake生成。
代码使用C ++（和QML）。
我正在创建一个QtQuick窗口，它使用.qml文件来生成其内容。

当我从 Visual Studio （2017 RC）运行构建的应用程序时，该应用程序提供了一个共同的

“组件未就绪” 错误消息。

但如果我运行相同的.exe文件手动，一切正常完美。

我怀疑我的CMakeLists中必定存在某种错误，导致Visual Studio在错误的位置搜索文件，但我不知道这可能是什么错误。

C ++代码失败部分：

...
QQmlComponent guiComponent(qmlEngine,
    QUrl::fromLocalFile(APP_RESOURCES"/qml/GUI.qml"));

guiRoot = qobject_cast<QQuickItem *>(guiComponent.create());
guiRoot->setParentItem(mainWindow->contentItem());
qDebug() << guiComponent.errors();
...

我的CMakeLists：

cmake_minimum_required(VERSION 3.8)

set(PROJECT_NAME "[MyProjectName]")
set(APP_NAME "[MyProjectName]")

project(${PROJECT_NAME})

set(CMAKE_AUTORCC ON )
set(CMAKE_AUTOUIC ON )
set(CMAKE_AUTOMOC ON )

set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake_modules;${CMAKE_MODULE_PATH}")

find_package(Qt5 REQUIRED Quick QuickWidgets)
find_package(QtImageLoader REQUIRED HINTS ${CMAKE_SOURCE_DIR}/addons/QtImageLoader/cmake)
find_package(AssimpModelLoader REQUIRED HINTS ${CMAKE_SOURCE_DIR}/addons/AssimpModelLoader/cmake)
find_package(GPUEngine REQUIRED geGL geSG)

set(SRC_ROOT "${CMAKE_SOURCE_DIR}/src")
set(SRC_FILES "")
set(INCLUDE_DIRS "")

add_subdirectory(src)
list(APPEND SRC_FILES ${src_SRC_FILES})
list(APPEND INCLUDE_DIRS ${src_INCLUDE_DIRS})

message("Located source files:")
FOREACH(_FILE ${SRC_FILES})
    message("- ${_FILE}")
ENDFOREACH()
message("Located include directories:")
FOREACH(_DIRE ${INCLUDE_DIRS})
    message("- ${_DIRE}")
ENDFOREACH()

source_group(TREE ${SRC_ROOT} PREFIX "src" FILES ${SRC_FILES})

add_executable(${APP_NAME} ${SRC_FILES})

target_include_directories(${APP_NAME} PUBLIC ${INCLUDE_DIRS})

target_link_libraries(${APP_NAME} Qt5::Quick Qt5::QuickWidgets geGL geSG AssimpModelLoader QtImageLoader)

set_target_properties(${APP_NAME} PROPERTIES COMPILE_DEFINITIONS "APP_RESOURCES=\"Data\"")

set_property(TARGET ${APP_NAME} PROPERTY FOLDER "${APP_NAME}")

add_custom_command(TARGET ${APP_NAME} POST_BUILD
    COMMAND ${CMAKE_COMMAND} -E copy_directory  "${CMAKE_SOURCE_DIR}/libs/$<CONFIG>"
                                                "$<TARGET_FILE_DIR:[MyProjectName]>"

    COMMAND ${CMAKE_COMMAND} -E copy_directory  "${CMAKE_SOURCE_DIR}/resources"
                                                "$<TARGET_FILE_DIR:[MyProjectName]>/Data"
)

编辑：我现在很长时间（几个月）遇到这个问题并且没有费心去解决它，因为手动运行应用程序就足够了。但现在我想使用Visual Studio的调试工具而我不能。

Answer 1

添加

VS_DEBUGGER_WORKING_DIRECTORY "$(OutDir)"

到我的目标属性

set_target_properties(${APP_NAME} PROPERTIES COMPILE_DEFINITIONS "APP_RESOURCES=\"Data\""
                                             VS_DEBUGGER_WORKING_DIRECTORY "$(OutDir)")

解决了这个问题。

有关其他解决方案，请查看上面的vre评论。

从Visual Studio运行应用程序会导致错误（由CMake生成）

1 个答案: