传递/返回Cython Memoryviews与NumPy Arrays

Question

我正在编写Python代码来加速二进制图像中标记对象的区域属性功能。以下代码将根据对象的索引计算二进制图像中标记对象的边界像素数。 main（）函数将遍历二进制图像“mask”中的所有标记对象，并计算每个对象的边框像素数。

我想知道在这个Cython代码中传递或返回变量的最佳方法是什么。变量可以是NumPy数组，也可以是类型化的Memoryviews。我已经弄乱了以不同格式传递/返回变量，但无法推断出最佳/最有效的方式。我是Cython的新手，所以Memoryviews对我来说仍然相当抽象，两种方法之间是否存在差异仍然是个谜。我正在使用的图像包含100,000多个标记对象，因此这些操作需要相当高效。

总结：

何时/应该将我的变量作为类型化的Memoryviews而不是NumPy数组传递/返回以进行非常重复的计算？有没有一种方法是最好的还是它们完全相同？

%%cython --annotate

import numpy as np
import cython
cimport numpy as np

DTYPE = np.intp
ctypedef np.intp_t DTYPE_t

@cython.boundscheck(False)
@cython.wraparound(False)
def erode(DTYPE_t [:,:] img):

    # Image dimensions
    cdef int height, width, local_min
    height = img.shape[0]
    width = img.shape[1]

    # Padded Array
    padded_np = np.zeros((height+2, width+2), dtype = DTYPE)
    cdef DTYPE_t[:,:] padded = padded_np
    padded[1:height+1,1:width+1] = img

    # Eroded image
    eroded_np = np.zeros((height,width),dtype=DTYPE)
    cdef DTYPE_t[:,:] eroded = eroded_np

    cdef DTYPE_t i,j
    for i in range(height):
        for j in range(width):
            local_min = min(padded[i+1,j+1], padded[i,j+1], padded[i+1,j],padded[i+1,j+2],padded[i+2,j+1])
            eroded[i,j] = local_min
    return eroded_np


@cython.boundscheck(False)
@cython.wraparound(False)
def border_image(slice_np):

    # Memoryview of slice_np
    cdef DTYPE_t [:,:] slice = slice_np

    # Image dimensions
    cdef Py_ssize_t ymax, xmax, y, x
    ymax = slice.shape[0]
    xmax = slice.shape[1]

    # Erode image
    eroded_image_np = erode(slice_np)
    cdef DTYPE_t[:,:] eroded_image = eroded_image_np

    # Border image
    border_image_np = np.zeros((ymax,xmax),dtype=DTYPE)
    cdef DTYPE_t[:,:] border_image = border_image_np
    for y in range(ymax):
        for x in range(xmax):
            border_image[y,x] = slice[y,x]-eroded_image[y,x]
    return border_image_np.sum()


@cython.boundscheck(False)
@cython.wraparound(False)
def main(DTYPE_t[:,:] mask, int numobjects, Py_ssize_t[:,:] indices):

    # Memoryview of boundary pixels
    boundary_pixels_np = np.zeros(numobjects,dtype=DTYPE)
    cdef DTYPE_t[:] boundary_pixels = boundary_pixels_np

    # Loop through each object
    cdef Py_ssize_t y_from, y_to, x_from, x_to, i
    cdef DTYPE_t[:,:] slice
    for i in range(numobjects):
        y_from = indices[i,0]
        y_to = indices[i,1]
        x_from = indices[i,2]
        x_to = indices[i,3]
        slice = mask[y_from:y_to, x_from:x_to]
        boundary_pixels[i] = border_image(slice)

    return boundary_pixels_np

Answer 1

Memoryview是Cython的最新成员，旨在与原始np.ndarray语法相比有所改进。出于这个原因，他们稍微偏爱。尽管如此，它通常不会产生太大的差异。以下是一些注意事项：

速度

对于速度而言，它非常差别很小 - 我的经验是，作为功能参数的记忆视图稍微慢一些，但它几乎不值得担心。

概论

Memoryviews旨在与任何具有Python缓冲区接口的类型（例如标准库array模块）一起使用。键入为np.ndarray仅适用于numpy数组。原则上，memorviews可以支持偶数wider range of memory layouts，它可以更容易地与C代码连接（实际上我从未真正看到它有用）。

作为返回值

当从Cython返回一个数组到Python代码时，用户可能会对numpy数组比使用memoryview更高兴。如果您正在使用记忆浏览，则可以执行以下任一操作：

return np.asarray(mview)
return mview.base

易于编译

如果您正在使用np.ndarray，则必须在np.get_include()文件中设置包含setup.py的包含目录。您不必使用内存视图执行此操作，这通常意味着您可以跳过setup.py并仅使用cythonize命令行命令或pyximport来执行更简单的项目。

并行化

与numpy数组（如果你想使用它）相比，这是内存视图的大优势。它不需要全局解释器锁来获取内存视图的片段，但它适用于numpy数组。这意味着以下代码大纲可以与内存视图并行工作：

cdef void somefunc(double[:] x) nogil:
     # implementation goes here

cdef double[:,:] 2d_array = np.array(...)
for i in prange(2d_array.shape[0]):
    somefunc(2d_array[i,:])

如果您没有使用Cython的并行功能，则不适用。

cdef类

您可以将memoryviews用作cdef类的属性，但不能用np.ndarray s。您（当然）可以使用numpy数组作为无类型object属性。