Question

是否可以在邮箱处理器上等待，以下代码在F＃interactive中工作，但有没有办法在应用程序或单元测试中等待它？

[<TestMethod>]
member this.TestMailboxProcessor() =
    let mailboxProcessor = MailboxProcessor<string>.Start(fun inbox ->
        async {
            while true do
            let! msg = inbox.Receive()
            printfn "agent got message %s" msg // too late, UnitTest exits
        }
    )

    mailboxProcessor.Post "ping"
    Console.WriteLine "message posted" // I see this in the console
    Assert.IsTrue(true)

Answer 1

在这种情况下，这是不可能的，但您可以定义消息类型以包含AsyncReplyChannel<'t>，然后允许您使用MailboxProcessor.PostAndReply而不是发布。这样调用代码可以（同步或异步）等待响应值，或至少表示处理已完成。

您修改后的源代码可能如下所示：

[<TestMethod>]
member this.TestMailboxProcessor() =
    let mailboxProcessor =
        MailboxProcessor<string * AsyncReplyChannel<unit>>.Start(fun inbox ->
            async {
                while true do
                let! msg, replyChannel = inbox.Receive()
                printfn "agent got message %s" msg
                (* 
                  Reply takes a value of the generic param of
                  AsyncReplyChannel<'t>, in this case just a unit
                *)
                replyChannel.Reply()
            }
        )

    (*
      You can't create an AsyncReplyChannel<'t> value, but this does it for you.
      Also always, always use timeouts when awaiting message replies. 
    *)
    mailboxProcessor.PostAndReply(
        (fun replyChannel -> "ping", replyChannel),
        timeout = 1000)
    (* This gets printed only after the message has been posted and processed *)
    Console.WriteLine "message posted"
    Assert.IsTrue(true)

MailboxProcessors虽然有点棘手，但请确保始终使用超时，否则如果代码出现错误，或者异常导致消息循环中断，则代码将永远挂起。测试不好，生产更糟糕。

Answer 2

您应该使用PostAndAsyncReply或PostAndReply（阻止版本）

let replyAgent = MailboxProcessor.Start(fun inbox ->
    let rec loop() = 
        async {
            let! (replyChannel: AsyncReplyChannel<_>), msg = inbox.Receive()
            replyChannel.Reply (sprintf "replied for message: %A" msg)
            return! loop()
        }
    loop() )

let reply = replyAgent.PostAndReply(fun replCh -> replCh, "Hi")
printfn "%s" reply //prints "replied for message: Hi"

等待邮箱处理器

2 个答案: