Question

我使用的是crystal language，到目前为止它还很棒。不幸的是，我觉得我的代码变得有点太乱了，各处都有类型。

例如：

  # ---------=====----++---
  # Grab characters
  # ---------=====----++---
  def handle_character_list(msg, client)
    result = {} of String => Array(Tuple(Int64, String, String, Int16, Int8)) | Int32 | Int16 | Int64 | String

    result["characters"] = db.query_all "select character_id, character_name, DATE_FORMAT(created, '%b:%d:%Y:%l:%i:%p') AS created, level, cc from rpg_characters where user_id = ? ", client.user_id,
      as: {Int64, String, String, Int16, Int8}

    result["max_char_slots"] = client.user_data["max_char_slots"]

    puts result
  end

在查看db.query_all method时，它说：

返回一个数组，其中每行的值被读取为给定类型

如上所述，为什么我需要再次将这些类型显式设置为我的result变量，如果它们将被返回？

我觉得我做错了什么，并且赞赏任何建议/见解。

Answer 1

跳出来的第一件事就是哈希类型的大小。您似乎以与Ruby相同的方式使用Hash。唐＆＃39;吨

在Ruby或其他动态语言中，Hash es或对象用作通用数据容器，几乎与未命名的类一样。在Crystal中，哈希对于键具有单一类型，对于值具有单一类型，这使得它们不适合该任务。您想告诉Crystal更多有关数据结构的信息，因此您不必再重复这些内容。

首先要做的是查看result对象。它可以简单地转换为record Result：

record Result,
  characters: Array({Int64, String, String, Int16, Int8}),
  max_char_slots: Int32

然后该方法变为

def handle_character_list(msg, client)
  sql = <<-SQL
    SELECT character_id, character_name, DATE_FORMAT(created, '%b:%d:%Y:%l:%i:%p') AS created, level, cc
    FROM rpg_characters
    WHERE user_id = ?
    SQL
  characters = db.query_all sql, client.user_id, as: {Int64, String, String, Int16, Int8}

  max_char_slots = client.user_data["max_char_slots"]

  Result.new(characters, max_char_slots)
end

但是，通过查看方法，可能只在一个地方使用此Result记录 - 从此方法返回数据。在这种情况下，你不太可能想给它一个更正式的名字。在这种情况下，您可以使用NamedTuple。他们有点像匿名记录。

def handle_character_list(msg, client)
  sql = <<-SQL
    SELECT character_id, character_name, DATE_FORMAT(created, '%b:%d:%Y:%l:%i:%p') AS created, level, cc
    FROM rpg_characters
    WHERE user_id = ?
    SQL

  {
    characters: db.query_all(sql, client.user_id, as: {Int64, String, String, Int16, Int8}),
    max_char_slots: client.user_data["max_char_slots"]
  }
end

更进一步，我们可以看到一个＆＃34;字符＆＃34;也是一种类型：

class Character
  getter id : Int64
  getter name : String
  getter created : Time
  getter level : Int16
  getter cc : Int8

  def initialize(@id, @name, @created, @level, @cc)
  end
end

然后我们可以使用DB.mapping来定义Character类在数据库中的外观。

class Character
  DB.mapping({
    id: Int64,
    name: String.
    created: Time,
    level: Int16,
    cc: Int8
  })

  def initialize(@id, @name, @created, @level, @cc)
  end
end

此定义与前一个定义相同，因为DB.mapping会自动为我们生成getter。

def handle_character_list(msg, client)
  sql = <<-SQL
    SELECT character_id, character_name, created, level, cc
    FROM rpg_characters
    WHERE user_id = ?
    SQL

  {
    characters: db.query_all(sql, client.user_id, as: Character),
    max_char_slots: client.user_data["max_char_slots"]
  }
end

更进一步，我将其提取为两种方法，每种方法只做一件事，而且我可能会使client.user_data类型更安全：

def characters_for_user(user_id)
  sql = <<-SQL
    SELECT character_id, character_name, created, level, cc
    FROM rpg_characters
    WHERE user_id = ?
    SQL
  db.query_all(sql, user_id, as: Character)
end

def handle_character_list(msg, client)
  {
    characters: characters_for_user(client.user_id),
    max_character_slots: client.user_data.max_char_slots
  }
end

这只是我对如何编写您已经展示的代码的思考过程。我对你的代码和数据库做了很多假设，这可能是错误的（即＆＃34;创建＆＃34;是mysql中的DATETIME）。我试图展示一个思考过程，而不是一个完成的解决方案。希望有所帮助。

如何处理Crystal中的冗余类型？

1 个答案: