Question

我在xml中有这个代码我想通过“inicial”属性进行分组但是没办法。我留下了当前的xml和xsl代码。

我曾尝试使用密钥进行分组，但没有办法可视化分组，对不起我的英文

相关链接：

http://www.microhowto.info/howto/group_xml_elements_by_key_using_xslt1.html

https://www.codeproject.com/Articles/1849/Grouping-XML-using-XSLT

Answer 1

如果限制为xslt 1，则可以使用muenchian分组方法：

http://www.jenitennison.com/xslt/grouping/muenchian.html

在你的情况下，这将有效：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:key name="inicial" match="contacte" use="@inicial"/>

    <xsl:template match="/">
        <html>
            <head>
                <title>Contactes</title>
                <link rel="stylesheet" href="agenda.css"/>
            </head> 
            <body>
                <h1>Contactes</h1>
                <xsl:call-template name="mostrar_contactes"/>
            </body>
        </html>
    </xsl:template>

    <xsl:template name="mostrar_contactes">
        <xsl:for-each select="agenda/contacte[count(.|key('inicial', @inicial)[1]) = 1]">

            <h4><xsl:value-of select="@inicial" /></h4>

            <xsl:for-each select="key('inicial', @inicial)">
                <xsl:sort select="cognom1"/>
                <div class="contacte">
                    <xsl:if test="foto=''">
                        <img src="imatges/perfilneutre.jpg"/>
                    </xsl:if>

                    <xsl:if test="foto!=''">
                        <img src="imatges/{foto}"/>
                    </xsl:if>

                    <h2 class="nom"><xsl:value-of select="nom"/></h2>
                    <h2><xsl:value-of select="cognom1"/></h2>
                    <h3><xsl:value-of select="telefons/telmovil"/></h3>
                </div>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Answer 2

我没有查看您的相关链接，但请查看this page on Muenchian Grouping。它在解释XSLT 1.0中的分组方面做得很好。

您没有提供所需的输出作为代码，因此下面的示例只是添加了分组。您可能需要调整它以获得所需的显示。

XSLT 1.0

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:key name="i" match="contacte" use="@inicial"/>

  <xsl:template match="/">
    <html>
      <head>
        <title>Contactes</title>
        <link rel="stylesheet" href="agenda.css"/>
      </head> 
      <body>
        <h1>Contactes</h1>
        <xsl:call-template name="mostrar_contactes"/>
      </body>
    </html>
  </xsl:template>

  <xsl:template name="mostrar_contactes">
    <xsl:for-each select="agenda/contacte[count(.|key('i',@inicial)[1])=1]">
      <xsl:sort select="cognom1"/>

      <h4><xsl:value-of select="@inicial" /></h4>

      <xsl:apply-templates select="key('i',@inicial)"/>

    </xsl:for-each>
  </xsl:template>

  <xsl:template match="contacte">
    <div class="contacte">
      <xsl:if test="foto=''">
        <img src="imatges/perfilneutre.jpg"/>
      </xsl:if>

      <xsl:if test="foto!=''">
        <img src="imatges/{foto}"/>
      </xsl:if>

      <h2 class="nom"><xsl:value-of select="nom"/></h2>
      <h2><xsl:value-of select="cognom1"/></h2>
      <h3><xsl:value-of select="telefons/telmovil"/></h3>
    </div>
  </xsl:template>

</xsl:stylesheet>

小提琴：http://xsltfiddle.liberty-development.net/3NzcBsC

按键分组XML元素

2 个答案: