具有命名参数的Groovy准备语句

Question

我使用以下方法使用JDBC Prepared Statement执行命名参数。有什么建议可以改善这个吗？

import java.sql.*;

def sqlQuery = "select * from table where col1=:col1 and col2=:col2"
def namedParameters =[
  ['ColumnName':'col1','Value':'test', 'DataType': 'int'],
  ['ColumnName':'col2','Value':'testsdfdf', 'DataType':'string'],
];

PreparedStatement stmt;

namedParameters.eachWithIndex{ k, v -> 
println "Index: " + v
println "Name: " + k.ColumnName
println "Value: " + k.Value

//To replace named parameters with ?
sqlQuery  = sqlQuery .replace(":" + k.ColumnName, "?")
println sqlQuery 

println "DataType: " + k.DataType

switch(k.DataType.toLowerCase())
{
    case('int'):
    stmt.setInt(v+1, k.Value)
    break;

    case('string'):
    stmt.setString(v+1, k.Value)
    break;

    default:
    stmt.setObject(v+1, k.Value)
}

};

println "End"

1. 我正在进行字符串替换以使用？
替换命名参数
2. 根据提供的地图，识别数据类型，将其设置为PreparedStatement

Answer 1

您可以使用groovy.sql.Sql类及其execute(Map params, String query, Closure processResults方法。请考虑以下示例脚本：

sql.groovy ：

@Grab(group='com.h2database', module='h2', version='1.4.197')

import groovy.sql.Sql

// (1) Configure JDBC connection (use H2 in-memory DB in this example)
def config = [
        url:'jdbc:h2:mem:test',
        user:'sa',
        password:'',
        driver: 'org.h2.Driver'
]

// (2) Connect to the database
def sql = Sql.newInstance(config.url, config.user, config.password, config.driver)

// (3) Create table for testing
sql.execute '''
     create table test (
         id integer not null,
         name varchar(50)
     )
'''

// (4) Insert some test data
def query = 'insert into test (id, name) values (?,?)'
sql.withBatch(3, query) { stmt ->
    stmt.addBatch(1, 'test 1')
    stmt.addBatch(2, 'test 2')
    stmt.addBatch(3, 'test 3')
}

// (5) Execute SELECT query
sql.execute([id: 1, name: 'test 1'], 'select * from test where id >= :id and name != :name', { _, result ->
    result.each { row ->
        println "id: ${row.ID}, name: ${row.NAME}"
    }
})

最后一部分展示了如何使用带有命名参数的预准备语句。在此示例中，我们要列出id大于或等于1且name不等于test 1的所有行。

sql.execute()方法的第一个参数是一个包含命名参数的映射（每个key映射到SQL查询中的:key。第二个参数是您的SQL查询，其中:key格式用于命名参数。第三个参数是定义处理业务逻辑的闭包 - result包含一个地图列表（例如，在这种情况下为[[ID: 2, NAME: test 2], [ID:3 name: test 3]]），您必须定义如何处理此结果。

控制台输出

id: 2, name: test 2
id: 3, name: test 3

sql.eachRow()替代

或者，您可以改为使用sql.eachRow(String sql, Map params, Closure closure)：

sql.eachRow('select * from test where id > :id', [id: 1], { row ->
    println "id: ${row.ID}, name: ${row.NAME}"
})

它将产生相同的输出。

Answer 2

使用Groovy SQL，您甚至可以使用GString作为SQL查询。

实施例

// Define bind variables
def  keyX = 1
def  keyY = 'row1'

查询

groovyCon.eachRow("select x,y from mytab where x  = ${keyX} and y  = ${keyY}")  {println it}

将以下查询发送到DB：

 select x,y from mytab where x = :1  and y = :2

Groovy SQl非常方便且有用，除了一些特殊情况（例如，您需要在循环中重用prepareStatement），您必须回退到纯JDBC。