Question

我有一个尺寸为4D的数据集，例如100（宽）x 100（高）x 2048（能量通道）x 20（帧）。是否有任何功能或方法将相同宽度，高度和能量通道的3D数据立方体（框架）附加到4D数据集的末尾？最后，4D数据集应为100 * 100 * 2048 * 21.

Answer 1

没有以这种方式扩展图像对象的命令。

您必须将其作为手动副本执行。（不幸的是，这需要额外的记忆。）

number sx = 100
number sy = 100
number sz = 100
number sf = 10

image before := RealImage( "Before", 4, sx, sy, sz, sf )
before = icol
image addFrame := RealImage( "Frame", 4, sx, sy, sz )
addFrame = irow

image after := RealImage( "After", 4, sx, sy, sz, sf + 1)
after.SliceN( 4,4, 0,0,0,0, 0,sx,1, 1,sy,1, 2,sz,1, 3,sf,1 ) = before
after.SliceN( 4,4, 0,0,0,sf, 0,sx,1, 1,sy,1, 2,sz,1, 3,1,1 ) = addFrame
before.showimage()
after.ShowImage()

如果这是一个问题，您也可以使用流命令直接将数据（仅限值，无元数据）流式传输到缓冲存储器或硬盘上。只有在最后，您才能将数据流式传输到尺寸合适的图像变量中。

最后，根据您的应用程序，您可以考虑将新数据作为标记组添加到标记列表（可以附加）。你可以存储＆＃34;图像＆＃34;作为标签（TagGroupSetTagAsArray()）。同样，你可以创建一个完整的＆＃39;图像在稍后的时间点形成此信息。

number sx = 100
number sy = 100
number sz = 100
number sf = 10

tagGroup FrameTags = NewTagGroup()
tagGroup FrameList = FrameTags.TagGroupGetOrCreateTagList( "frames" )
FrameTags.TagGroupSetTagAsLong( "X Size", sx )
FrameTags.TagGroupSetTagAsLong( "Y Size", sy )
FrameTags.TagGroupSetTagAsLong( "Z Size", sz )
// Add frames whenever you need .....
for( number f = 0; f < sf; f++ )
{
    image addFrame := RealImage( "Frame", 4, sx, sy, sz )
    addFrame = random()
    FrameList.TagGroupInsertTagAsArray( f, addFrame )
}
// Handle taggroup as you want. (Add to global tags, add to image, store to disc... )
FrameTags.TagGroupOpenBrowserWindow( "frames", 0 )

// Whenever needed, reconstruct image from frames
number nsx, nsy, nsz
FrameTags.TagGroupGetTagAsLong( "X Size", nsx )
FrameTags.TagGroupGetTagAsLong( "Y Size", nsy )
FrameTags.TagGroupGetTagAsLong( "Z Size", nsz )
TagGroup nFrameList
FrameTags.TagGroupGetTagAsTagGroup( "frames", nFrameList )
number nsf = nFrameList.TagGroupCountTags()

image after := RealImage( "After", 4, nsx, nsy, nsz, nsf )
for( number f = 0; f < nsf; f++ )
{
    image addFrame := RealImage( "Frame", 4, sx, sy, sz )
    FrameList.TagGroupGetIndexedTagAsArray( f, addFrame )
    after.SliceN( 4,4, 0,0,0,f, 0,sx,1, 1,sy,1, 2,sz,1, 3,1,1) = addFrame
}

after.ShowImage()

如何将n维图像附加到（n + 1）维图像的末尾？

1 个答案: