Question

我希望通过使用地图的键和值对来实现文档中的字符串查找和替换。由于2个映射值，我目前拥有的代码似乎返回2个字符串。我希望返回一个字符串，其中大括号中的值将替换为映射中的值。

let $text:='On ${date} the value of alert is ${alerts}'
    let $params:= map:map()
    let $noop:=map:put($params,'date','TESTINGDATE')
    let $noop:=map:put($params,'alerts','TESTALERT')


    let $formatted-message:=for $keys in map:keys($params)
                            let $message:=fn:replace($text,fn:concat('\$\{',$keys,'\}'),map:get($params,$keys))
                            return $message

    return $formatted-message

Answer 1

您可以使用递归函数：

declare function local:replace-all($text, $key, $rest, $params) 
{
  if (fn:empty($key)) then
    $text
  else
    local:replace-all(fn:replace($text, fn:concat('\$\{',$key,'\}'), map:get($params,$key)), 
                      fn:head($rest), 
                      fn:tail($rest), 
                      $params)

};

let $text:='On ${date} the value of alert is ${alerts}'
let $params:= map:map()
let $noop:=map:put($params,'date','TESTINGDATE')
let $noop:=map:put($params,'alerts','TESTALERT')
let $keys := map:keys($params)
return
  local:replace-all($text, fn:head($keys), fn:tail($keys), $params)

或者您可以使用fn:fold-left()：

let $text:='On ${date} the value of alert is ${alerts}'
let $params:= map:map()
let $noop:=map:put($params,'date','TESTINGDATE')
let $noop:=map:put($params,'alerts','TESTALERT')
let $keys := map:keys($params)
return
  fn:fold-left(
    function($text, $keys) {
      let $key := fn:head($keys)
      return 
        fn:replace($text, fn:concat('\$\{',$key,'\}'), map:get($params,$key))
    },
    $text,
    $keys
  )

两者都产生：

On TESTINGDATE the value of alert is TESTALERT

fn：replace在迭代时返回一个字符串

1 个答案: