Question

我有一个代码可以成功地将多个工作簿的特定命名工作表中的数据合并到特定的主工作簿表中。

但是，代码也会合并空行，其中包含某种格式。在我的例子中，源表有boderlines，空行中没有任何值。我尝试使用SourceRange.Range(FirstCell & ":" & RDB_Last(3, .Cells)).ClearFormats，但无法解决问题。

如果我手动清除源文件中的格式，保存文件，然后运行它正常运行的代码。但这在实时情况下是不可能的。

VBA的新手。请帮忙。提前致谢。

我的文件在G Drive中分享：Sample Data

注意：RDM_Last是一个用于确定具有值的最后一行/单元格的函数。我在主代码下添加了代码。

守则：

Sub MergeAllWorkbooks2()
Dim FirstCell As String
Dim MyPath As String, FilesInPath As String
Dim myFiles() As String
Dim SourceRcount As Long, FNum As Long
Dim mybook As Workbook, BaseWks As Worksheet
Dim sourceRange As Range, destrange As Range
Dim rnum As Long, CalcMode As Long

' Change this to the path\folder location of your files.
MyPath = "C:\Users\zatin.dharmapuri\Desktop\3. 2018\Raw Data Month wise\Jan-2018"

' Add a slash at the end of the path if needed.
If Right(MyPath, 1) <> "\" Then
    MyPath = MyPath & "\"
End If

' If there are no Excel files in the folder, exit.
FilesInPath = Dir(MyPath & "*.xl*")
If FilesInPath = "" Then
    MsgBox "No files found"
    Exit Sub
End If

' Fill the myFiles array with the list of Excel files
' in the search folder.
FNum = 0
Do While FilesInPath <> ""
    FNum = FNum + 1
    ReDim Preserve myFiles(1 To FNum)
    myFiles(FNum) = FilesInPath
    FilesInPath = Dir()
Loop

' Set various application properties.
With Application
    CalcMode = .Calculation
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False
End With

' The sheet name for the data to be copied to.
Set BaseWks = ThisWorkbook.Sheets("Sheet3")
rnum = 2

' Loop through all files in the myFiles array.
If FNum > 0 Then
    For FNum = LBound(myFiles) To UBound(myFiles)
        Set mybook = Nothing
        On Error Resume Next
        Set mybook = Workbooks.Open(MyPath & myFiles(FNum))
        On Error GoTo 0

        If Not mybook Is Nothing Then
            On Error Resume Next

            'Change this range to fit your own needs.
            'With mybook.Worksheets("Defect Analysis Reports")
               'Set sourceRange = .Range("A5:J104")
            'End With

        With mybook.Worksheets("Defect Analysis Reports")
            FirstCell = "A5"
            Set sourceRange = .Range(FirstCell & ":" & RDB_Last(3, .Cells))
            .Range(FirstCell & ":" & RDB_Last(3, .Cells)).ClearFormats
            'Test if the row of the last cell >= then the row of the FirstCell
            If RDB_Last(1, .Cells) < .Range(FirstCell).Row Then
                Set sourceRange = Nothing

            End If
        End With

            If Err.Number > 0 Then
                Err.Clear
                Set sourceRange = Nothing
            Else
                ' If source range uses all columns then
                ' skip this file.
                If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                    Set sourceRange = Nothing
                End If
            End If
            On Error GoTo 0

            If Not sourceRange Is Nothing Then

                SourceRcount = sourceRange.Rows.Count

                If rnum + SourceRcount >= BaseWks.Rows.Count Then
                    MsgBox "There are not enough rows in the target worksheet."
                    BaseWks.Columns.AutoFit
                    mybook.Close savechanges:=False
                    GoTo ExitTheSub
                Else

                    ' Copy the file name in column A.
                    With sourceRange
                        BaseWks.Cells(rnum, "A"). _
                                Resize(.Rows.Count).Value = myFiles(FNum)
                    End With

                    ' Set the destination range.
                    Set destrange = BaseWks.Range("B" & rnum)

                    ' Copy the values from the source range
                    ' to the destination range.
                    With sourceRange
                    Set destrange = destrange. _
                                        Resize(.Rows.Count, .Columns.Count)
                    End With
                    destrange.Value = sourceRange.Value

                    rnum = rnum + SourceRcount
                End If
            End If
            mybook.Close savechanges:=False
        End If

    Next FNum
    'BaseWks.Columns.AutoFit
End If
       ExitTheSub:
       'Restore the application properties.
     With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .Calculation = CalcMode
End With

MsgBox "All Data has been merged successfully"
End Sub

修改

RDM_Last功能代码：

Function RDB_Last(choice As Integer, rng As Range)
'Ron de Bruin, 5 May 2008
' 1 = last row
' 2 = last column
' 3 = last cell
Dim lrw As Long
Dim lcol As Integer

    Select Case choice

    Case 1:
        On Error Resume Next
        RDB_Last = rng.Find(What:="*", _
                            after:=rng.Cells(1), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
        On Error GoTo 0

    Case 2:
        On Error Resume Next
        RDB_Last = rng.Find(What:="*", _
                            after:=rng.Cells(1), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByColumns, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Column
        On Error GoTo 0

    Case 3:
        On Error Resume Next
        lrw = rng.Find(What:="*", _
                       after:=rng.Cells(1), _
                       Lookat:=xlPart, _
                       LookIn:=xlFormulas, _
                       SearchOrder:=xlByRows, _
                       SearchDirection:=xlPrevious, _
                       MatchCase:=False).Row
        On Error GoTo 0

        On Error Resume Next
        lcol = rng.Find(What:="*", _
                        after:=rng.Cells(1), _
                        Lookat:=xlPart, _
                        LookIn:=xlFormulas, _
                        SearchOrder:=xlByColumns, _
                        SearchDirection:=xlPrevious, _
                        MatchCase:=False).Column
        On Error GoTo 0

        On Error Resume Next
        RDB_Last = rng.Parent.Cells(lrw, lcol).Address(False, False)
        If Err.Number > 0 Then
            RDB_Last = rng.Cells(1).Address(False, False)
            Err.Clear
        End If
        On Error GoTo 0

    End Select
End Function

Answer 1

使用.Range(FirstCell & ":" & RDB_Last(3, .Cells)).ClearFormats代替Range(FirstCell & ":" & RDB_Last(3, .Cells)).ClearFormats。

如果您想在使用With时参考特定工作表内的范围，则应使用范围前的点（即.Range）来引用范围。目前您的范围可能会参考其他一些表格。

Answer 2

确定，这得到了解决，这是一个愚蠢的错过。这不是格式化问题。一些文件在单元格BI520中具有潜在数据：CU531。这搞砸了LastCell计算。

来自AlfaFrog https://www.excelforum.com/members/235459.html

感谢时间专家。

合并数据前清除源表格格式

2 个答案: