Question

有没有办法可以按日期降序检索人工制品？

我目前在这里有以下脚本作为例子：

import org.sonatype.nexus.repository.storage.Asset
import org.sonatype.nexus.repository.storage.Query
import org.sonatype.nexus.repository.storage.StorageFacet

import groovy.json.JsonOutput
import groovy.json.JsonSlurper

def request = new JsonSlurper().parseText(args)
assert request.groupId: 'groupId parameter is required'
assert request.repoName: 'repoName parameter is required'
assert request.startDate: 'startDate parameter is required, format: yyyy-mm-dd'

log.info("Gathering Asset list for repository: ${request.repoName} as of startDate: ${request.startDate}")

def repo = repository.repositoryManager.get(request.repoName)
StorageFacet storageFacet = repo.facet(StorageFacet)
def tx = storageFacet.txSupplier().get()

tx.begin()

Iterable<Asset> assets = tx.
    findAssets(Query.builder()
      .where('group = ').param(request.groupId)
      .and('last_updated > ').param(request.startDate)
      .build(), [repo])
def urls = assets.collect { "/repository/${repo.name}/${it.name()}" }

tx.commit()

def result = JsonOutput.toJson([
    assets  : urls,
    since   : request.startDate,
    repoName: request.repoName
])
return result

使用：

Query.builder()
          .where('group = ').param(request.groupId)
          .and('last_updated > ').param(request.startDate)
          .build()
def urls = assets.collect { "/repository/${repo.name}/${it.name()}" }

有没有办法我们可以更改上面的脚本以按日期降序检索事物？

Answer 1

您只需添加后缀即可。

Query.builder()
          .where('group = ').param(request.groupId)
          .and('last_updated > ').param(request.startDate)
          .suffix('order by last_updated desc')
          .build()
def urls = assets.collect { "/repository/${repo.name}/${it.name()}" }

Nexus正在幕后使用OrientDB。您可以在此处找到查询示例： https://orientdb.com/docs/2.0/orientdb.wiki/Tutorial-SQL.html

Nexus 3 Query构建器如何按降序检索人工制品

1 个答案: