Question

如何在XSLT中围绕单个单词包装span标签（或任何标签）？我正在使用XSLT1，但每次尝试都会卡住。

基本上，我想传入段落（或文本字符串）：

<p>This is my text!</p>

并像这样包装每个单词，保留每个单词之间的空格和标点符号：

<p><span class="word-1">This</span> <span class="word-2">is</span> <span class="word-3">my</span> <span class="word-4">text!</span>

主要是出于演示目的，我很感激任何帮助

Answer 1

此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="pSeparators">&#xA;&#x9;&#x20;,.;:?!()'"</xsl:param>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="p/text()" name="tokenize">
        <xsl:param name="pString" select="."/>
        <xsl:param name="pMask"
                   select="translate(.,translate(.,$pSeparators,''),'')"/>
        <xsl:param name="pCount" select="1"/>
        <xsl:choose>
            <xsl:when test="not($pString)"/>
            <xsl:when test="$pMask">
                <xsl:variable name="vSeparator"
                              select="substring($pMask,1,1)"/>
                <xsl:variable name="vString"
                              select="substring-before($pString,$vSeparator)"/>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString" select="$vString"/>
                    <xsl:with-param name="pMask"/>
                    <xsl:with-param name="pCount" select="$pCount"/>
                </xsl:call-template>
                <xsl:value-of select="$vSeparator"/>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="pString"
                               select="substring-after($pString,$vSeparator)"/>
                    <xsl:with-param name="pMask"
                                    select="substring($pMask,2)"/>
                    <xsl:with-param name="pCount"
                                    select="$pCount + boolean($vString)"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <span class="word-{$pCount}">
                    <xsl:value-of select="$pString"/>
                </span>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

输出：

<p><span class="word-1">This</span> <span class="word-2">is</span> <span class="word-3">my</span> <span class="word-4">text</span>!</p>

注意：由多个分隔符进行标记。修改：更好的名字。将空白字符添加到分隔符序列。

Answer 2

一个简单的递归命名模板应该可以解决这个问题：

  <xsl:template name="wordsInTags">
      <xsl:param name="text"
                 select="."/>
      <xsl:param name="index"
                 select="1"/>
      <xsl:choose>
        <xsl:when test="contains($text, ' ')">
          <span class="word-{$index}">
            <xsl:value-of select="substring-before($text, ' ')"/>
          </span>
          <xsl:text> </xsl:text>
          <xsl:call-template name="wordsInTags">
            <xsl:with-param name="text">
              <xsl:value-of select="substring-after($text, ' ')"/>
            </xsl:with-param>
            <xsl:with-param name="index">
              <xsl:value-of select="$index + 1"/>
            </xsl:with-param>
          </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
          <span class="word-{$index}">
            <xsl:value-of select="$text"/>
          </span>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>

然后只需为需要包装单词的元素调用它：

    <xsl:template match="p">
      <p>
        <xsl:call-template name="wordsInTags"/>
      </p>
    </xsl:template>

快速将这些放在一起，所以可能需要更多的工作，但这应该让你开始。

使用XSLT包装标签中的单词

2 个答案: