Question

我是NUSMV的新手我正在尝试为重新组合41708建模一个数字码，但是用户无法做更多3错误。如果输入更多3错误，系统将进入状态bloked等待您输入要解锁的特殊代码。这是我的代码，如果你无法帮助我提出想法并建议完成代码。

MODULE main
VAR
val1 : {0,1,2,3,4,5,6,7,8};
location : {E1,E2,E3,E4,E5,succes,blocked,unblocked,verified};
cpt : 0..3;
block : boolean;
NumberEnter : 0..5 ;


ASSIGN
init(cpt):=0;
init(block):=FALSE;
init(location):=E1;


next(location):= case 
        (location=E1) &(cpt!=3)  & (block!=TRUE) :E2 ;
        (location=E2) & (cpt!=3) & (block!=TRUE) :{E3,E1,blocked};

        (location=E3) & (cpt!=3) & (block!=TRUE) :{E2,E1,blocked} ;
        (location=E4) & (cpt!=3) & (block!=TRUE) :{E1,E5,blocked} ;
        (location=E5) & (cpt!=3) & (block!=TRUE) :{E1,blocked} ;
        TRUE:blocked;
        esac;


next(pas):= case 
            NumberEnter<5 :NumberEnter+ 1 ;

        TRUE:0;
        esac;

Image of Model

Answer 1

一种可能的解决方案是：

MODULE main()
VAR
    in_digit  : 0 .. 9;
    in_signal : boolean;
    dc : digicode(in_digit, in_signal);


MODULE digicode(in_digit, in_signal)
VAR
    state   : { RUN, OK, ERROR };
    idx     : 0 .. 4;
    counter : 0 .. 3;

DEFINE
    pwd := [4, 1, 7, 0, 8];

INIT state = RUN & idx = 0 & counter = 0;

ASSIGN
    next(state) := case
        state = RUN   & pwd[idx]  = in_digit & idx < 4     : RUN;
        state = RUN   & pwd[idx]  = in_digit               : OK;
        state = RUN   & pwd[idx] != in_digit & counter < 3 : RUN;
        state = RUN   & pwd[idx] != in_digit               : ERROR;
        state = ERROR & in_signal                          : RUN;
        TRUE                                               : state;
    esac;

    next(counter) := case
        state = RUN & pwd[idx] != in_digit & counter < 3 : counter + 1;
        state = RUN & pwd[idx]  = in_digit               : counter;
        TRUE                                             : 0;
    esac;

    next(idx) := case
        state = RUN & pwd[idx]  = in_digit & idx < 4 : idx + 1;
        state = RUN & pwd[idx] != in_digit           : 0;
        TRUE                                         : 0;
    esac;

--
-- the following invariants nicely restrict the set of viable
-- transitions when inputs can be ignored
--
INVAR
    in_signal     -> state = ERROR;

INVAR
    state = ERROR -> in_digit = 0;

INVAR
    state = OK    -> in_digit = 0;

解决方案假设一个人只能通过输入in_digit一次输入一个数字，并且有一个单独的控制信号in_signal来重置设备。

设备有三种可能的状态：

RUN：设备从in_digit读取输入数字，并将其与固定密码序列进行比较
OK：设备在过去的某个时间识别输入序列，现在忽略了任何进一步的输入
ERROR：用户输入的输入尝试次数过多，设备忽略任何输入数字，直到in_signal为true。

在模型的最后，我添加了三个INVAR约束，这些约束从与我们无关的边缘修剪过渡空间，因为某些输入在某些时刻被忽略。忽略这些输入可以更容易地手动模拟系统。

运行示例，使用NuSMV：

~$ NuSMV -int
~$ reset; read_model -i digicode.smv; go; pick_state -iv; simulate -iv -k 30
~$ quit

另一种更简单的方法是同时为digicode提供5个输入数字。通过这种方式，可以从模型中删除idx和pwd，使其更加简单。

Nusmv的Digicode

1 个答案: