Question

我有一个FMX应用程序（但在VCL中应该是相同的），TabControl显示10个选项卡。根据应用程序状态和用户权限，选项卡设置为可见或不可见。

效果很好，但我不喜欢

每个人都在一起，并以主要形式混淆
并且标签内容即使永远不可见也会被初始化。

所以我想到了使用当标签变得可见时创建的框架。

每个帧只能存在一次，应该可以很容易地从另一个帧操作一个帧（另一个帧上的访问控制）。

我喜欢优雅的解决方案和简短的代码：）

这是我已经找到的，非常好，但它已经很老了： Replacing TabSheets with Frames - by Dan Miser

Answer 1

此解决方案为每个帧都有一个全局变量。所有框架都可以在其实现部分中使用主窗体单元，并且可以轻松访问其他框架及其所有控件，即使不将其他框架添加到uses子句中也是如此。

标签开始不可见，其框架未初始化。 TabA.Activate;显示标签并设置焦点。 TabA.Frame.Label1可以轻松访问该Frame上的控件。 TabA.Visible:= False;隐藏了标签并释放了框架。

泛型在这里非常有用，我喜欢它。

非常欢迎改进的想法...

type
  TFormMain = class(TForm)
    TabControl: TTabControl;
    TabInfo: TTabItem;
    procedure FormCreate(Sender: TObject);
  private
    procedure AddTab<T: TTabItem>(out Tab: T);
  public
    TabA: TTabItemFrame<TFrameA>;
    TabB: TTabItemFrame<TFrameB>;
    TabC: TTabItemFrame<TFrameC>;
  end;

var
  FormMain: TFormMain;

implementation

procedure TFormMain.FormCreate(Sender: TObject);
begin
  AddTab(TabA);
  AddTab(TabB);
  AddTab(TabC);

  TabA.Activate;
end;

procedure TFormMain.AddTab<T>(out Tab: T);
begin
  Tab:= TabControl.Add(T) as T;
end;

---------------------------------------------------------------------
unit _FrameBase;

interface

uses
  System.Classes, FMX.Forms, FMX.TabControl;

type
  TFrameBase = class abstract(TFrame)
  public
    class function GetTitle: string; virtual; abstract;
  end;

  TTabItemFrame<T: TFrameBase> = class(TTabItem)
  private
    FFrame: T;
  protected
    procedure Hide; override;
    procedure Show; override;
  public
    constructor Create(AOwner: TComponent); override;
    function Activate: T;
    property Frame: T read FFrame;
  end;

implementation

{ TTabItemFrame }

constructor TTabItemFrame<T>.Create(AOwner: TComponent);
begin
  inherited;
  Text:= T.GetTitle;
  Visible:= False;
end;

function TTabItemFrame<T>.Activate: T;
begin
  Visible:= True;
  TabControl.ActiveTab:= Self;
  Result:= FFrame;
end;

procedure TTabItemFrame<T>.Hide;
begin
  inherited;
  FFrame.DisposeOf;
  FFrame:= nil;
end;

procedure TTabItemFrame<T>.Show;
begin
  inherited;
  FFrame:= T.Create(Self);
  FFrame.Parent:= Self;
end;

end.

---------------------------------------------------------------------

type
  TFrameA = class(TFrameBase)
    Label1: TLabel;
  public
    class function GetTitle: string; override;
  end;

implementation

// if it's necessary to access components or methods of
// any other frame or the main form directly
uses
  _FormMain;

//...

更新：我决定使用表格代替我的FMX应用程序的框架，因为框架在设计时不能使用样式。副作用是我可以使用表格标题来代替类函数。

将表单嵌入到tabitem中有点棘手：

constructor TFormTabBase.Create(AOwner: TComponent);
begin
  inherited;
  while ChildrenCount > 0 do Children[0].Parent:= AOwner as TTabItem;
end;

procedure TTabItemForm<T>.Show;
begin
  inherited;
  FFormTab:= T.Create(Self);
  Text:= FFormTab.Caption;
end;

如何在自己的单元中使用TTabControl的每个选项卡/使用TFrame而不是选项卡？

1 个答案: