Question

我正在逐步学习装配中的启动代码。

我找到了以下程序集启动代码。但我完全理解仍然有问题。

到目前为止，据我所知，

首先，在第1行执行后，

然后转到第2行，

然后转到第5行，

然后转到第6行，将0x40002001加载到r1寄存器，

然后转到第7行，转到r1的寄存器地址（PC更新为0x40002001）

直到这里，我明白了。

但我无法理解第3行和第4行的目的和意义。

请您告诉我第3和第4行的意义和目的是什么？

1    .section .text                                                             
2        .globl main

3        .word   0x40002000 
4        .word   main+1

5     main:                                                                      
6         ldr   r1, st0                                                       
7         bx    r1           

8        .align 4
9     st0:                                                                   
10       .word   0x40002001

Answer 1

您需要阅读cortex-m3的文档。这是来自ARM的网站，不一定是芯片供应商。

简短的回答是.words用于描述向量表，这些不是指令。其参数含义可能不同的.align用于确保常量对齐以避免数据中止。

地址0x00000000处的第一项/字是在复位时加载到堆栈指针中的值。第二个字是复位向量。作为一个拇指指令集机器，它想要一个在向量表中设置lsbit的地址。

然后代码分支到0x40002000，lsbit被剥离，但是bx必须工作。（PC得到0x40002000而不是0x40002001）

您没有指定汇编语言（汇编程序），如果要使用gnu汇编程序，那么您可以将其清理一些：

.cpu cortex-m3
.thumb

    .globl _start
_start:
    .word   0x40002000
    .word   main

    .thumb_func
main:
     ldr   r1, st0
     bx    r1

    .align
st0:
    .word   0x40002001

产

Disassembly of section .text:

00000000 <_start>:
   0:   40002000    andmi   r2, r0, r0
   4:   00000009    andeq   r0, r0, r9

00000008 <main>:
   8:   4900        ldr r1, [pc, #0]    ; (c <st0>)
   a:   4708        bx  r1

0000000c <st0>:
   c:   40002001    andmi   r2, r0, r1

现在的问题是如何在重置之前将程序存入0x40002000的内存？

你可以在gnu汇编程序中使用.align混淆或可能的浪费（在.align之后使用错误的值）

.cpu cortex-m3
.thumb

    .globl _start
_start:
    .word   0x40002000
    .word   main

    .thumb_func
main:
     ldr   r1, =0x40002001
     bx    r1

Disassembly of section .text:

00000000 <_start>:
   0:   40002000    andmi   r2, r0, r0
   4:   00000009    andeq   r0, r0, r9

00000008 <main>:
   8:   4900        ldr r1, [pc, #0]    ; (c <main+0x4>)
   a:   4708        bx  r1
   c:   40002001    andmi   r2, r0, r1

对齐是为了避免这样的事情导致错误：

.cpu cortex-m3
.thumb

    .globl _start
_start:
    .word   0x40002000
    .word   main

    .thumb_func
main:
     nop
     ldr   r1, st0
     bx    r1

.align
st0: .word 0x40002001

<。> .align导致填充添加到上面不需要的位置，因为该值落在它已对齐的位置。

Disassembly of section .text:

00000000 <_start>:
   0:   40002000    andmi   r2, r0, r0
   4:   00000009    andeq   r0, r0, r9

00000008 <main>:
   8:   46c0        nop         ; (mov r8, r8)
   a:   4901        ldr r1, [pc, #4]    ; (10 <st0>)
   c:   4708        bx  r1
   e:   bf00        nop

00000010 <st0>:
  10:   40002001    andmi   r2, r0, r1

这也适合你，在这种情况下用零填充，没有使用对齐，让它将数据放在池中

.cpu cortex-m3
.thumb

    .globl _start
_start:
    .word   0x40002000
    .word   main

    .thumb_func
main:
     nop
     ldr   r1, =0x40002001
     bx    r1

它没有很好地拆解，所以intel十六进制输出表单显示了发生了什么。

:100000000020004009000000C046014908470000E8
:04001000012000408B
:00000001FF

与上述相同，但填充为0x0000

0x4708 (bx r1)
0x0000
0x40002001

如何用＆＃34; .word＆＃34;来解释汇编启动代码

1 个答案: