Question

我能够创建我想要的大部分内容：在同一个表中并排显示两个单向表格（报告累积百分比）。这很好，但我需要一些格式化的帮助。玩具示例：

sysuse auto, clear
eststo clear
eststo a: estpost tabulate rep78 if foreign==0
eststo b: estpost tabulate rep78 if foreign==1
esttab, cells("cumpct(fmt(2))") ///
    varlabels("a" "b")      ///
    nonumber nomtitle noobs ///
    collabels("a" "b")

这会产生以下结果：

--------------------------------------
                        a            a
--------------------------------------
1                    4.17             
2                   20.83             
3                   77.08        14.29
4                   95.83        57.14
5                  100.00       100.00
Total                                 
--------------------------------------

我怎么能：

摆脱总线和
使列标签名称不同？我希望将第二列称为b，而不是a。我在协作中使用了不同的内容变体（a b，"a b"，""a" "b""），但似乎没有任何效果。

Answer 1

其中任何一个都应该做到这一点：

sysuse auto, clear
eststo clear
qui eststo a: estpost tabulate rep78 if foreign==0
qui eststo b: estpost tabulate rep78 if foreign==1
esttab, cells("cumpct(fmt(2))") ///
    nonumber mtitles("a" "b") nodepvars noobs drop(Total) collabels(none)

eststo clear
qui eststo a, title("a"): estpost tabulate rep78 if foreign==0
qui eststo b, title("b"): estpost tabulate rep78 if foreign==1
esttab, cells("cumpct(fmt(2))") ///
    nonumber mtitles nodepvars noobs drop(Total) collabels(none)

我更喜欢第二种语法，因为我喜欢在估计它们的地方命名模型。

两者都会产生类似的东西：

--------------------------------------
                        a            b
--------------------------------------
1                    4.17             
2                   20.83             
3                   77.08        14.29
4                   95.83        57.14
5                  100.00       100.00
--------------------------------------

使用esttab格式化表

1 个答案: