Question

我正在帮助非盈利组织创建输入控件。

以下公式返回正确的结果，但I15 < 0的情况除外，它返回FALSE而不是将结果返回为空白（即""）。

我在论坛中阅读了其他帖子，回答了类似的问题，但找不到我错过""的地方？请帮忙。

=+IF(I15>0,IF(AND(F15="",G15=""),"Please input expense code and program code",
  IF(F15="","Please input expense code",
  IF(G15="","Please put program code",
  IF(B15="","Please input date",
  IF(C15="","Please specify receipt attached as yes or no",
  IF(D15="","Please specify vendor name","")))))))

Answer 1

当遵循嵌套表达式的逻辑时，通常有助于扩展和缩进每个嵌套级别，以便您可以清楚地看到分支：

=IF(I15>0,
    IF(AND(F15="",G15=""),
        "Please input expense code and program code",
        IF(F15="",
            "Please input expense code",
            IF(G15="",
                "Please put program code",
                IF(B15="",
                    "Please input date",
                    IF(C15="",
                        "Please specify receipt attached as yes or no",
                        IF(D15="",
                            "Please specify vendor name",
                            ""
                        )
                    )
                )
            )
        )
    ),
    ""
)

在这里，我在最后的右括号之前添加了一个逗号和空字符串，以构成最外层ELSE语句的if参数。

您也不需要在公式开头+。

嵌套IF返回错误

1 个答案: