Question

是否有办法通过提供非本地主机的smtp服务器凭据使用UTL_SMTP方法发送电子邮件。

即。 SMTP服务正在其他地方运行，但不是https安全，我想使用utl_smtp包，但我没有看到任何带有smtp服务器ID或密码的函数参数

Answer 1

如果您想使用UTL_SMTP，请在致电utl_smtp.open_connection时提供SMTP主机。

示例代码（取自Oracle docs）;

DECLARE
  c UTL_SMTP.CONNECTION;

  PROCEDURE send_header(name IN VARCHAR2, header IN VARCHAR2) AS
  BEGIN
    UTL_SMTP.WRITE_DATA(c, name || ': ' || header || UTL_TCP.CRLF);
  END;

BEGIN
  c := UTL_SMTP.OPEN_CONNECTION('smtp-server.acme.com');
  UTL_SMTP.HELO(c, 'foo.com');
  UTL_SMTP.MAIL(c, 'sender@foo.com');
  UTL_SMTP.RCPT(c, 'recipient@foo.com');
  UTL_SMTP.OPEN_DATA(c);
  send_header('From',    '"Sender" <sender@foo.com>');
  send_header('To',      '"Recipient" <recipient@foo.com>');
  send_header('Subject', 'Hello');
  UTL_SMTP.WRITE_DATA(c, UTL_TCP.CRLF || 'Hello, world!');
  UTL_SMTP.CLOSE_DATA(c);
  UTL_SMTP.QUIT(c);
EXCEPTION
  WHEN utl_smtp.transient_error OR utl_smtp.permanent_error THEN
    BEGIN
      UTL_SMTP.QUIT(c);
    EXCEPTION
      WHEN UTL_SMTP.TRANSIENT_ERROR OR UTL_SMTP.PERMANENT_ERROR THEN
        NULL; -- When the SMTP server is down or unavailable, we don't have
              -- a connection to the server. The QUIT call raises an
              -- exception that we can ignore.
    END;
    raise_application_error(-20000,
      'Failed to send mail due to the following error: ' || sqlerrm);
END;

如果您的smtp服务器接受PLAIN，LOGIN或CRAM-MD5身份验证，您还需要调用utl_smtp.auth，例如：

DECLARE
  c utl_smtp.connection;
BEGIN
  c := utl_smtp.open_connection(
      host => 'smtp.example.com',
      port => 25,
      wallet_path => 'file:/oracle/wallets/smtp_wallet',
      wallet_password => 'password',
      secure_connection_before_smtp => FALSE);
  UTL_SMTP.STARTTLS(c);
  UTL_SMTP.AUTH(
      c => c,
      username => 'scott',
      password => 'password'
      schemes  => utl_smtp.all_schemes);
END;

也就是说，如果您使用的是APEX，您可能需要考虑使用APEX_MAIL。您可以在APEX实例设置中配置主机。

文档：

UTL_SMTP：https://docs.oracle.com/cd/E11882_01/appdev.112/e40758/u_smtp.htm#ARPLS074
APEX_MAIL：https://docs.oracle.com/database/apex-5.1/AEAPI/APEX_MAIL.htm

使用smtp服务器凭据从oracle apex UTL_SMTP发送电子邮件

1 个答案: