Question

我试图在Haxe中使用宏制作一些黑暗魔法，我有一个名为Entity的类，我想添加一个包含static和private修饰符的池：

Pool.hx：

package exp;

class Pool<T> {
    public function new(clazz:Class<T>) {

    }
}

Entity.hx：

package exp;

@:build(exp.PoolBuilder.build())
class Entity {
    public function new(){}
}

PoolBuilder.hx：

package exp;

import haxe.macro.Context;
import haxe.macro.Expr;
import haxe.macro.Type;

class PoolBuilder {
    static public macro function build() : Array<Field> {
        var fields = Context.getBuildFields();
        var clazz = Context.getLocalClass();

        var typePath = { name:"Pool", pack:["exp"], params: [TPType(TPath({name: "Entity", pack: ["exp"]}))] }
        var pool = macro new $typePath(/* clazz? */);
        fields.push({
            name: "_pool",
            access: [APrivate, AStatic],
            pos: Context.currentPos(),
            kind: FVar(macro: exp.Pool, pool)
        });

        return fields;
    }
}

我对typePath参数有问题，并将Class<T>作为参数传递给构造函数。编译器显示以下错误：

exp / Entity.hx：3：字符1-7：exp.Pool的类型参数数量无效

exp / Entity.hx：4：第4-6行：在此类中定义

有人知道怎么解决吗？

Answer 1

手动构建字段有点单调乏味 - 我建议改用class reification，您可以将字段表示为常规Haxe代码：

macro class {
    static var _pool = new Pool(/* clazz */);
}

这会绕过＆＃34;无效的类型参数数量＆＃34;完全问题 - 只需让类型推断成功，并省略new Pool()中的类型参数。

构造函数调用的参数当然是可变的，因此我们仍然需要使用一些expression reification。 exp.Entity是字段表达式，因此我们必须使用$p{}。我们可以通过组合clazz.pack和clazz.name来构建所需的类型路径：

class PoolBuilder {
    static public macro function build():Array<Field> {
        var fields = Context.getBuildFields();
        var clazz = Context.getLocalClass().get();
        var path = clazz.pack.concat([clazz.name]); // ["exp", "Entity"]

        var extraFields = (macro class {
            static var _pool = new Pool($p{path});
        }).fields;
        return fields.concat(extraFields);
    }
}

这会生成以下代码（可以在exp/Entity.dump -D dump=pretty中看到）：

static var _pool:exp.Pool<exp.Entity> = new exp.Pool(exp.Entity);

Answer 2

如果您希望按fields.push({...})添加字段而不是使用类具体化，则可以使用null中的FVar(null, pool)作为类型来触发类型推断：

static public macro function build() : Array<Field> {
    var fields = Context.getBuildFields();
    var clazz = Context.getLocalClass().get();

    var path = clazz.pack.concat([clazz.name]); // ["exp", "Entity"]
    var pool = macro new exp.Pool($p{path});
    fields.push({
        name: "_pool",
        access: [APrivate, AStatic],
        pos: Context.currentPos(),
        kind: FVar(null, pool)
    });

    return fields;
}

这是path使用@ gama11技巧。这将生成与@ gama11 answer完全相同的代码（并且可以以相同的方式进行检查）。

使用Haxe宏实例化一个带参数

2 个答案: