Question

我有一个包含查询的表，例如：

select text from queries;

    TEXT
1   select item from items where item_no between :low_item_no and :high_item_no and description <> :irellevant

查询已经包含绑定变量的占位符。

值本身存在于变量表中：

select * from vars;

    ID  NAME               VALUE
1   1   low_item_no        100
2   2   high_item_no       300
3   3   irellevant_desc    old

我有一个包，它接受查询并用

执行它

执行立即声明

但是如何绑定这些变量？

我不知道在这样的查询中有多少变量，它不是静态的。

我希望有办法做这样的事情：

Execute immedaite my_query_str using v_array_of_vars;

到目前为止，我不知道有什么方法可以做这样的事情，只有变量列表例如：

Execute immedaite my_query_str using v_1, v_2, v_3;

谢谢！

Answer 1

我认为您无法使用execute immediate执行此操作，因为在编译时太多未知，因此您必须使用the dbms_sql package代替。

这是一个基于通用查询ID获取查询和变量的快速演示。此假设 vars.name中的值实际上与queries.text中的绑定变量名称匹配，并且我还没有包含针对该问题或其他潜在问题的任何检查或错误处理，或处理多个选择列表项或数据类型 - 只是基础：

declare
  my_query_str queries.text%type;
  my_cursor pls_integer;
  my_result pls_integer;
  my_col_descs dbms_sql.desc_tab2;
  my_num_cols pls_integer;
  my_item items.item%type;

begin
  select text into my_query_str from queries where query_id = 42;
  dbms_output.put_line(my_query_str);

  -- open cursor
  my_cursor := dbms_sql.open_cursor;
  -- parse this query
  dbms_sql.parse(my_cursor, my_query_str, dbms_sql.native);
  -- bind all variables by name; assumes bind variables match vars.name
  for r in (select name, value from vars where query_id = 42) loop
    dbms_output.put_line('Binding ' || r.name || ' || with <' || r.value ||'>');
    dbms_sql.bind_variable(my_cursor, r.name, r.value);
  end loop;

  my_result := dbms_sql.execute(my_cursor);
  dbms_output.put_line('execute got: ' || my_result);

  dbms_sql.describe_columns2(my_cursor, my_num_cols, my_col_descs);

  dbms_sql.define_column(my_cursor, 1, my_item, 30); -- whatever size matches 'item'

  -- fetch and do something with the results
  while true loop
    my_result := dbms_sql.fetch_rows(my_cursor);
    if my_result <= 0 then
      exit;
    end if;

    dbms_sql.column_value(my_cursor, 1, my_item);
    dbms_output.put_line('Got item: ' || my_item);
  end loop;

  dbms_sql.close_cursor(my_cursor);
end;
/

你似乎并不需要一个阵列;但如果你想，你可以创建并填充一个关联数组作为名称/值对，然后使用该fir绑定。

这只是一个起点;您可能必须处理返回的未知数量和/或类型的列，但如果是这样的情况，则有意义地处理它们将是一个挑战。也许您需要将查询结果作为引用游标返回，这甚至更简单;使用SQL * Plus variable和print命令进行演示：

var rc refcursor;

declare
  my_query_str queries.text%type;
  my_cursor pls_integer;
  my_result pls_integer;

begin
  select text into my_query_str from queries where query_id = 42;
  dbms_output.put_line(my_query_str);

  -- open cursor
  my_cursor := dbms_sql.open_cursor;
  -- parse this query
  dbms_sql.parse(my_cursor, my_query_str, dbms_sql.native);
  -- bind all variables by name; assumes bind variables match vars.name
  for r in (select name, value from vars where query_id = 42) loop
    dbms_output.put_line('Binding ' || r.name || ' || with <' || r.value ||'>');
    dbms_sql.bind_variable(my_cursor, r.name, r.value);
  end loop;

  my_result := dbms_sql.execute(my_cursor);
  dbms_output.put_line('execute got: ' || my_result);

  :rc := dbms_sql.to_refcursor(my_cursor);
end;
/

print rc

请注意，在此方案中，您不要关闭PL / SQL块内的光标。

你也可以转换为参考光标，然后在你的程序中从那里获取 - 那里a bulk-collect example in the docs - 但你又需要知道选择列表的数量和类型要做的事情。

传递数组以绑定变量

1 个答案: